使用变量引用类属性？

Question

我有一个包含 name、id、office 和 officeto 字段的员工集合 (employees)。 我需要在等距的列中打印出这些信息。所以我需要找到最长的字符串名称、office、officeto 的长度...并添加空格以使列等距。
我知道如何使用记录集将字段名称发送到函数中。 所以我的问题是......是否可以通过使用变量（类似于rst！[fieldname]）来引用类属性（name、office、officeto）。 我尝试将其设置为字段上的记录集循环，但它无法编译。错误是 class.property 未定义。

Public Function PropertyLen(ByVal Property As String, ByRef Employees As colEmployees) As Integer

'This function uses a passed in class property, and returns the len of the longest class property in collection

On Error GoTo ErrorHandler:

Dim Emp As clsEmployee
Dim intLen As Integer 
Dim lngCount As Long

For lngCount = 1 To Employees.Count

       Set Emp = Employees.Item(lngCount)

       If Len(Trim(Emp.Property)) > intLen Then
            intLen = Len(Trim(Emp.Property))
       End If

       Set Emp = Nothing  
Next

    FieldLen = intLen

ExitFunc:
'clean up
    Set Emp = Nothing
    Exit Function

ErrorHandler:
    modErrorHandler.DisplayUnexpectedError Err.Number, Err.Description
    Resume ExitFunc

End Function

Answer 1

有一个用于测试的示例类模块clsSample：

Public Prop1
Public Prop2
Public Prop3
Public Prop4

您可以使用原生 VBA 函数 CallByName() 按名称获取属性值：

Sub TestGetProperty()

    Set objSample = New clsSample
    objSample.Prop1 = "TEST"
    Debug.Print CallByName(objSample, "Prop1", VbGet) ' TEST

End Sub

如果你不想使用CallByName()，那么你可以求助于jscript语法object[property]：

Sub TestGetProperty()

    Set objSample = New clsSample
    objSample.Prop1 = "TEST"
    Debug.Print GetProperty(objSample, "Prop1") ' TEST

End Sub

Function GetProperty(objSample, strName)

    Static objHtmlfile As Object

    If objHtmlfile Is Nothing Then
        Set objHtmlfile = CreateObject("htmlfile")
        objHtmlfile.parentWindow.execScript "function GetProperty(sample, name) {return sample[name]}", "jscript"
    End If
    GetProperty = objHtmlfile.parentWindow.GetProperty(objSample, strName)

End Function

顺便说一句，还有另一个类似的解决方案允许evaluate a string into an object 和create a new class instance by the class name。

Answer 2

您可以创建一个包装函数，它接受一个对象和一个属性的字符串名称，并返回具有该名称的对象的属性。像这样的：

Function GetProperty(O As Object, property As String) As String
    Dim s As String
    property = LCase(property)
    Select Case property
        Case "name"
            s = O.Name
        Case "id"
            s = O.ID
        Case "office"
            s = O.Office
        Case "officeto"
            s = O.officeto
    End Select
    GetProperty = s
End Function

这主要是未经测试的（因为我不想实例化你的班级成员）但它能够例如当我评估 GetProperty(Sheets(1), "name") 时返回 Sheet1 的名称

Answer 3

其他答案对我不起作用。

我成功使用Eval()语句，例如：

Debug.Print Eval("objSample." & Prop1NamesArray(i))

其中Prop1NamesArray(i) 是要返回的属性名称的string array。