cython cdef 类 c 方法：如何在没有 python 开销的情况下从另一个 cython cdef 类调用它？

Question

我正在尝试在 cython 中实现通用排序算法。因此，我创建了以下模块，它在 sorter_t 类中实现了堆排序算法：

# file general_sort_c.pyx

from libc.stdint cimport int32_t
cdef bint bint_true = 1
cdef bint bint_false = 0

cdef class sorter_t:

    cdef object sortable_object

    def __init__(self,sortable_object):
        self.sortable_object = sortable_object

    cpdef sort_c(self):

        """
        https://en.wikipedia.org/wiki/Heapsort

        """

        cdef int32_t end
        cdef int32_t count = self.sortable_object.num_elements_int32

        self.heapify_c(count)

        end = count-1 
        while end > 0:
            self.sortable_object.swap_c(0,end)
            end = end - 1
            self.siftDown_c(0,end)

    cdef heapify_c(self,int32_t count):

        cdef int32_t start = (count - 2)/2   

        while start >= 0:
            self.siftDown_c(start, count-1)
            start -= 1

    cdef siftDown_c(self,int32_t start, int32_t end):

        cdef int32_t root = start
        cdef int32_t swap
        cdef int32_t child

        while root * 2 + 1 <= end:

            child = root * 2 + 1 
            swap = root

            # if "swap" < "child" then ...
            if self.sortable_object.lt_c(swap,child) == 1:
                swap = child

            if child+1 <= end and self.sortable_object.lt_c(swap,child+1) == 1:
                swap = child + 1

            if swap != root:
                self.sortable_object.swap_c(root,swap)
                root = swap
            else:
                return

当您定义sorter_t 类型的对象时，您必须提供一个sortable_object，它具有自己特定的cdef 函数lt_c（用于比较一个元素是否小于另一个）和swap_c（用于交换元素）。

例如，以下代码将定义并从列表中创建一个sortable_object，并将使用该sortable_object 测试“sorter_t”的实现。

import numpy
cimport numpy
from libc.stdint cimport int32_t
import general_sort_c

cdef class sortable_t:

    cdef public int32_t num_elements_int32
    cdef int32_t [:] mv_lista

    def __init__(self,int32_t [:] mv_lista):
        self.num_elements_int32 = mv_lista.shape[0]
        self.mv_lista = mv_lista

    cdef public bint lt_c(self, int32_t left, int32_t right):
        if self.mv_lista[left] < self.mv_lista[right]:
            return 1 # True
        else:
            return 0 # False

    cdef public bint gt_c(self, int32_t left, int32_t right):
        if self.mv_lista[left] > self.mv_lista[right]:
            return 1 # True
        else:
            return 0 # False

    cdef public swap_c(self, int32_t left, int32_t right):
        cdef int32_t tmp
        tmp = self.mv_lista[right]
        self.mv_lista[right] = self.mv_lista[left]
        self.mv_lista[left] = tmp

def probar():

    lista = numpy.array([3,4,1,7],dtype=numpy.int32)
    cdef int32_t [:] mv_lista = lista

    cdef sortable = sortable_t(mv_lista)
    cdef sorter = general_sort_c.sorter_t(sortable)
    sorter.sort_increasing_c()
    print list(lista)

编译.pyx 文件并在IPython 控制台中运行以下命令后，出现以下错误：

In [1]: import test_general_sort_c as tgs

In [2]: tgs.probar()      

...

 general_sort_c.sorter_t.siftDown_increasing_c (general_sort_c.c:1452)()
    132 
    133             #if mv_tnet_time[swap] < mv_tnet_time[child]:

--> 134             if self.sortable_object.lt_c(swap,child) == bint_true:
    135                 swap = child
    136 

AttributeError: 'test_general_sort_c.sortable_t' object has no attribute 'lt_c'

所以，问题在于函数lt_c 的实现在模块general_sort_c.pyx 中的代码中是不可见的。如果我使用 cpdef 而不是 cdef 定义函数 lt_c 它将起作用，但是您有很多 Python 开销。如何以cdef（“纯C”）的方式调用这个函数？

Answer 1

不幸的是，我不确定如何让它与融合类型一起使用，但其余的很简单：

test_general_sort_c.pyx 需要免费的test_general_sort_c.pxd：

from libc.stdint cimport int32_t

cdef class sortable_t:
    cdef public int32_t num_elements_int32
    cdef int32_t [:] mv_lista
    cdef public bint lt_c(self, int32_t left, int32_t right)
    cdef public bint gt_c(self, int32_t left, int32_t right)
    cdef public swap_c(self, int32_t left, int32_t right)

general_sort_c.pyx 必须是 cimport test_general_sort_c 并键入其 self.sortable_object 为 test_general_sort_c.sortable_t。

当然，如果您可以拥有多种受支持的类型，那就更好了。不过，我不确定你现在会怎么做。

---

此外，内置的 True 和 False 可以单独工作。

如果你更信任 Cython，你会意识到你可以写

cdef public bint lt_c(self, int32_t left, int32_t right):
    return self.mv_lista[left] < self.mv_lista[right]

cdef public bint gt_c(self, int32_t left, int32_t right):
    return self.mv_lista[left] > self.mv_lista[right]

cdef public swap_c(self, int32_t left, int32_t right):
    self.mv_lista[right], self.mv_lista[left] = self.mv_lista[left], self.mv_lista[right]

很好。 :)