指针中的 Fortran 多态性

Question

我正在尝试使用指针来创建对象之间的链接。使用 Fortran，代码如下：

 module base_pars_module
   type,abstract,public :: base_pars
   end type
 end module 
 module test_parameters_module
   use base_pars_module
   type, extends(base_pars) :: test_pars
     contains 
     procedure :: whoami
   end type
   contains
   function whoami(this) result(iostat)
     class( test_pars) :: this
     write(*,*) 'i am a derived type child of base_pars'
   end type
 end module
 module base_mask_module
   use base_pars module
     type, abstract , public :: base_mask
     class(base_pars),pointer :: parameters
   end type
end module
module test_mask_module
  use base_mask_module
  implicit none
  type, extends(base_mask) :: test_mask
  end type
end module
program driver
type(test_pars) , target :: par_Test
type(test_mask) :: mask_test
  iostat= par_test%whoami()
  mask_test%parameters=>par_test
  iostat=mask_test%parameters%whoami()
end program

parameters at base_mask_module 是一个带有 base_pars 类的指针。我想使用这个指针来引用 par_test 对象，它是扩展 base_pars 类型的 test_pars 类型。所以指针和目标具有相同的类。但是当我编译它时，它给出了一个错误：

 driver.f90:17.37:

iostat=mask_test%parameters%whoami()
                                  1
Error: 'whoami' at (1) is not a member of the 'base_pars' structure

这是一个错误还是我做错了什么？

Answer 1

当你有这样的多态性时，关于一个对象有两件事需要考虑：它的动态类型和它的声明类型。 test_mask (base_mask) 的 parameters 组件声明为

class(base_pars),pointer :: parameters

因此，此类组件已声明类型 base_pars。

来指针赋值

mask_test%parameters=>par_test

mask_test%parameters 具有与par_test 相同的动态类型：test_pars。不过，它是声明类型base_pars，当我们关心它的组件和绑定时，它是重要的声明类型。 base_pars确实没有whoami。

那么，您需要声明类型为par_test 的东西。在不更改派生类型的定义的情况下，您可以使用 select type 构造来做到这一点。

select type (pars => mask_test%parameters)
class is (par_test)
  iostat=pars%whoami()  ! pars of declared type par_test associated with mask_test%parameters
end select

也就是说，使用这种方法，事情很快就会变得非常乏味。总是使用select type，区分众多扩展类型，将是一个很大的束缚。另一种方法是确保声明的类型base_pars 具有绑定whoami。我们没有像上面那样改变主程序，而是改变模块base_pars_module：

module base_par_modules
  implicit none  ! Encourage good practice

  type,abstract,public :: base_pars
   contains
    procedure(whoami_if), deferred :: whoami
  end type

  interface
    integer function whoami_if(this)
      import base_pars    ! Recall we're in a different scope from the module
      class(base_pars) this
    end function
  end interface

end module

所以，我们在base_pars 中有一个延迟绑定，稍后会被扩展类型test_pars 中的绑定覆盖。则主程序中的mask_test%parameters%whoami() 是有效的，调用的函数是动态类型parameters 提供的函数。

这里的两种方法都解决了parameters 声明类型的绑定问题。哪个最适合您的实际问题取决于您的整体设计。

如果您知道您的类型层次结构都与基本类型有足够的共同点（也就是说，所有类型都将提供whoami 绑定），那么采用第二种方法是有意义的。当您有奇怪的特殊情况时，请使用第一种方法，我建议这种情况应该很少见。