为什么 MergeSort 函数会发生值限制？

Question

我在 List 上有一个非常简单的 MergeSort 实现。

/// Divide the list into (almost) equal halves
let rec split = function
    | [] -> [], []
    | [x] -> [x], []
    | x1::x2::xs -> let xs1, xs2 = split xs
                    x1::xs1, x2::xs2

/// Merge two sorted lists
let rec merge xs ys =
    match xs, ys with
    | [], _ -> ys
    | _, [] -> xs
    | x::xs', y::ys' when x <= y -> x::merge xs' ys
    | _, y::ys' -> y::merge xs ys' 

let rec mergeSort = function
    | [] -> []
    | xs -> let xs1, xs2 = split xs
            merge (mergeSort xs1) (mergeSort xs2)

但每当我尝试使用 F# Interactive 中的任何输入进行测试时：

let xs = mergeSort [1;4;3;2];;

遇到值限制错误：

错误 FS0030：值限制。值“xs”已被推断为 有泛型类型 val xs : '_a list when '_a : comparison 将 'xs' 定义为一个简单的数据项，使其成为具有显式参数的函数，或者，如果 你不打算让它是通用的，添加一个类型注释。

为什么会这样？有什么简单的修复方法？

Answer 1

您没有处理 mergeSort 中的 1 元素列表的特殊情况。 一般情况“太笼统”而无法推断出正确的类型。结果，编译器为函数推断出过于通用的类型（'a list -> 'b list），结果始终是通用列表（由于值限制，这是不允许的）。

如果你这样修复它，类型将被正确推断为 'a list -> 'a list。

let rec mergeSort = function
    | [] -> []
    | [x] -> [x]
    | xs -> let xs1, xs2 = split xs
            merge (mergeSort xs1) (mergeSort xs2)