如何在 Haskell 中添加两个类似 matlab 的列表？

Question

我想知道是否可以编写一个 Haskell 加法运算符来处理两个数字、两个数字列表、两个数字矩阵……等等。也就是说，是否可以定义一个<+> 以使以下所有工作都有效？：

1 <+> 2 = 3
[1] <+> [2] = [3]
[[1]] <+> [[2]] = [[3]]
...

我知道就像What is an idiomatic way to add lists in Haskell? 一样，我们可以为a 做+，为zipWith (+) 做[a]。 [[a]] 可能是 zipWith (zipWith (+))，沿着同一条线，依此类推……

但它可以使用一个运算符（就像 Matlab 一样）使用类型类或 Haskell 的其他功能来完成吗？

我知道这是合成糖，但如果可能的话它会很甜。

-- 更新--

我发现使用(Num a) 可能会出现问题，正如@DanielWagner 的回答中所解释的那样，对于基本情况，最好为Integer, Double 等单独定义它。

为了记录，我只是按照建议尝试了：

{-# LANGUAGE FlexibleInstances, UndecidableInstances #-}
class Additive a where (<+>) :: a -> a -> a
instance Num a => Additive a where (<+>) = (+)
instance Additive a => Additive [a] where (<+>) = zipWith (<+>)

或者

{-# LANGUAGE DefaultSignatures #-}
class Additive a where
    (<+>) :: a -> a -> a
    default (<+>) :: Num a => a -> a -> a
    (<+>) = (+)

在任何一种情况下，加载.hs 文件或评估[[1,2]] <+> [[3,4]] 时都会出错。

Answer 1

是的，有可能：

class Additive a where (<+>) :: a -> a -> a
instance Additive Integer where (<+>) = (+)
instance Additive a => Additive [a] where (<+>) = zipWith (<+>)

你在 ghci 中的三个测试用例：

*Main> 1 <+> 2
3
*Main> [1] <+> [2]
[3]
*Main> [[1]] <+> [[2]]
[[3]]

如果你想要很多 (<+>) = (+) 的实例，你可以使用 DefaultSignatures 将其设为默认实现：

{-# LANGUAGE DefaultSignatures #-}
class Additive a where
    (<+>) :: a -> a -> a
    default (<+>) :: Num a => a -> a -> a
    (<+>) = (+)

优点是某些实例可以很短，例如

instance Additive Integer
instance Additive Int
instance Additive Double
instance Additive Float

无需任何额外的方法定义即可按预期工作。