如何遍历除一张以外的所有工作表？

Question

我想遍历工作表，如果满足内部条件，则将其复制到我的“Controle”工作表中。

我的代码在没有循环的情况下工作。

我的工作表“Controle”中有一个列表，其中包含所有工作表中的所有彩色单元格。代码必须跳过名称为“Controle”的工作表，因为我在这里将单元格复制到。

Sub Dubbelewaarden()
Dim cell As Range
Dim sht As Worksheet
For Each sht In Worksheets
    If Not sht.Name <> "Controle" Then
        For Each cell In Range("A2", Range("A2").End(xlDown))
            If cell.Interior.ColorIndex = 3 Then
                cell.EntireRow.Copy Destination:=Sheets("Controle").Range("A" & Rows.Count).End(xlUp).Offset(1)
            End If
        Next cell
    End If
Next sht

End Sub
```

Answer 1

这只是将循环变量绑定到工作表的情况，否则将假定活动工作表。网上有很多参考。

Sub Dubbelewaarden()

Dim cell As Range
Dim sht As Worksheet

For Each sht In Worksheets
    If sht.Name <> "Controle" Then
        'tie reference to sheet in loop
        For Each cell In sht.Range("A2", sht.Range("A" & Rows.Count).End(xlUp))
            If cell.Interior.ColorIndex = 3 Then
                cell.EntireRow.Copy Destination:=Sheets("Controle").Range("A" & Rows.Count).End(xlUp).Offset(1)
            End If
        Next cell
    End If
Next sht

End Sub