使用属性“暂停”线程

Question

我有一个 TThread 对象，并希望能够通过程序主窗体上的按钮启动/停止线程。我一直在研究如何做到这一点，到目前为止，我有以下想法：

1. 当用户单击停止时终止并释放线程，并在用户单击开始时创建一个新线程。
2. 使用 sleep 来延迟线程（我不想这样做）
3. 有一个布尔属性来确定线程是否暂停。 Execute 中的代码仅在此布尔值为 false 时才会发生。

我倾向于#3。在主窗体中为 TThread 对象设置布尔属性是否是线程安全的？

我应该选择这些选项中的哪一个或更好的选择？这是我第一次使用线程，因此非常感谢您的帮助。

Answer 1

1.用户点击停止时终止并释放线程，点击开始时创建一个新线程。

如果开销很小，这当然是一种选择。

3. 有一个布尔属性来确定线程是否暂停。 Execute 中的代码仅在此布尔值为 false 时才会发生。

您可以这样做，但您必须定期检查该布尔值，如果设置，则进入等待循环，直到它被清除或线程被发出终止信号。

在主窗体中为 TThread 对象设置布尔属性是否是线程安全的？

它与调用 TThread.Terminate() 一样线程安全，只需设置布尔值 TThread.Terminated 属性。

我应该选择这些选项中的哪一个或更好的选择？

我使用选项 #4 - 使用信号事件而不是布尔值。例如：

type
  TMyThread = class(TThread)
  private
    FRunEvent, FTermEvent: TEvent;
    FWaitEvents: THandleObjectArray;
    procedure CheckPause;
  protected
    procedure Execute; override;
    procedure TerminatedSet; override;
  public
    constructor Create; reintroduce;
    destructor Destroy; override;
    procedure Pause;
    procedure Unpause;
  end;

constructor TMyThread.Create;
begin
  inherited Create(False);

  FRunEvent := TEvent.Create(nil, True, True, '');
  FTermEvent := TEvent.Create(nil, True, False, '');

  SetLength(FWaitEvents, 2);
  FWaitEvents[0] := FRunEvent;
  FWaitEvents[1] := FTermEvent;
end;

destructor TMyThread.Destroy;
begin
  FRunEvent.Free;
  FTermEvent.Free;
  inherited;
end;

procedure TMyThread.Execute;
begin
  while not Terminated do
  begin
    // do some work...
    CheckPause;
    // do some more work...
    CheckPause;
    // do some more work...
    CheckPause;
    //...
  end;
end;

procedure TMyThread.TerminatedSet;
begin
  FTermEvent.SetEvent;
end;

procedure TMyThread.CheckPause;
var
  SignaledEvent: THandleObject;
begin
  while not Terminated do
  begin
    case TEvent.WaitForMultiple(FWaitEvents, INFINITE, False, SignaledEvent) of
      wrSignaled: begin
        if SignaledEvent = FRunEvent then Exit;
        Break;
      end;
      wrIOCompletion: begin
        // retry
      end;
      wrError: begin
        RaiseLastOSError;
    end;
  end;
  SysUtils.Abort;
end;

procedure TMyThread.Pause;
begin
  FRunEvent.ResetEvent;
end;

procedure TMyThread.Unpause;
begin
  FRunEvent.SetEvent;
end;

Answer 2

在此处查看有关 Delphi 启动和停止线程的 wiki：http://docwiki.embarcadero.com/RADStudio/Berlin/en/Starting_and_Stopping_Threads

这适用于 Delphi 7。它可能适用于更早的版本，但我无法确认早期版本。