NetLogo：跳出嵌套的 foreach 循环

Question

我正在尝试使用 2 个排序海龟列表打破嵌套的 foreach 循环。 但是，netlogo 不仅离开了内部循环，还打破了整个过程。 我有一个类似下面的代码（这个是编造的，但结构完全相同）：

to do-something    
  let xturtles sort-by [ [a b] -> [birthday] of a > [birthday] of b ] turtles
  ;; construct an ordered set
  foreach xturtles [ the-xturtle ->
    ask the-xturtle [
      let xage birthday
      let yturtles sort-by [ [a b] -> [birthday] of a > [birthday] of b ] turtles with [birthday < xage] 
       ;; construct a second ordered set
      foreach yturtles [ the-yturtle ->
        let breakout-condition? false
        ask the-yturtle [
          if (hidden? ) [
            set breakout-condition? true
          ]
        ]
        if breakout-condition? [ stop ]
      ]
    ]
  ]
end

但是，当达到停止条件时，netlogo 会跳出整个过程，而不是继续外部循环（xturtles 循环）？

这是预期的行为吗？如果是这样，在这种情况下有什么好的做法？

谢谢！ 费利克斯

Answer 1

看起来甚至将stop 嵌套在同一过程中的额外ask 过程中也无济于事。但是，如果您需要快速修复，我认为您可以将第二个 foreach 循环替换为包含 stop 的独立过程作为解决方法。例如，此过程遵循与您的类似的格式，并且出现相同的问题 - 只要stop 被称为更广泛的foreach 退出。

to nest-foreach-example
  ca
  crt 1
  let xs [ 1 2 3 4 ]
  let ys [ 1 2 3 4 ]
  foreach xs [ 
    x ->
    foreach ys [ 
      y ->
      ask turtles [
        if y > x [
          stop
        ]
      ]
      print word x y 
    ]
  ]
end

这会打印出11。

但是，如果您创建一个自定义过程来代替“y”foreach 循环，它可以工作（有或没有ask turtles）：

to nest-foreach-example-turtles
  ca
  crt 1
  let xs [ 1 2 3 4 ]
  let ys [ 1 2 3 4 ]
  foreach xs [ 
    x ->
    for-y x ys 
  ]

end

to for-y [ x_ ys ]
  foreach ys [
    y ->
    ask turtles [
      if y > x_ [
        stop
      ]
    ]
    print word x_ y
  ]
end

输出：

11
21
22
31
32
33
41
42
43
44