带循环的 ms 访问查询以创建多个表

Question

我在 oracle 数据库中有一个表 - 它将有两列（项目名称，视图名称）。在该表中，当您过滤项目名称时，我们将获取与该项目相关的所有视图名称，再次基于这些视图名称，我们需要编写像 select * from projectname$viewaname; 这样的查询来获取该视图相关数据。

手动执行此操作对于每个项目都需要很长时间。所以我的想法是创建 MS ACCESS 数据库来为选定的项目创建表并将它们作为 excel 文件导出到C:\temp folder。

我需要您的帮助，以便在 MS Access 中一次性创建多个表（使用查询/直通查询或任何其他选项）从 oracle 数据库中获取数据。

为此，我创建了 MS 访问文件，创建了一个链接表（其中我有项目和视图名称）。

之后我创建了一个表单，使用项目字段作为链接表中的组合框并更新了设置，例如，这个表单应该在启动时打开。

当我打开访问文件时，此表单会自动打开并要求我输入 oracle 数据库用户 ID 和密码 - 输入凭据后，组合框正在更新，我可以在该列表中选择我的项目。

之后，我使用主表创建了一个查询，并根据表单中的选择应用了过滤条件。现在我得到了最终用户选择的项目的项目和视图名称等结果。

我需要你的帮助，例如，

现在我们在下表中有数据。

Project | Viewname
A       | A1  
A       | A2
A       | A3
A       | A4
A       | A5

查看单个视图数据的 SQL 查询是：

select * from projectname$view_name;

例如：select * from A$A1;

项目名称、视图名称和行数（视图）、视图中的列是动态的 - 将根据项目而变化。

我需要您的帮助来动态创建多个表（每个视图一个） - 请建议我最好的选择。

问候， 壁画

Answer 1

考虑迭代循环遍历记录集中的项目/视图名称查询并创建传递查询，然后导出到 Excel 电子表格。

Public Sub ImportOracleProjectViews()
    Dim db As Database, rst As Recordset, qdef As QueryDef
    Dim constr As String, strSQL As String, mkTBL As String

    Set db = CurrentDb
    ' ENTER QUERY HOLDING PROJECT AND VIEW NAMES '
    Set rst = db.OpenRecordset("QUERYNAME")

    ' DELETE TEMP QUERYDEF IF EXISTS '
    For Each qdef In db.QueryDefs
        If qdef.Name = "temp" Then
            db.QueryDefs.Delete ("temp")
        End If
    Next qdef

    If rst.RecordCount = 0 Then Exit Sub
    rst.MoveLast: rst.MoveFirst

    ' LOOP THROUGH EACH RECORD OF RECORDSET ' 
    Do While Not rst.EOF

        ' SQL STATEMENTS '
        strSQL = "SELECT * FROM " & rst!projectname & "$" & rst!viewname

        ' ORACLE CONNECTION STRING '
        constr = "ODBC;Driver={Microsoft ODBC for Oracle};Server=myServerAddress;" _
                              & "Uid=myUsername;Pwd=myPassword;"

        ' PASS THRU QUERY '
        Set qdef = db.CreateQueryDef("temp")
        qdef.Connect = constr
        qdef.SQL = strSQL
        qdef.Close

        ' EXPORT TO MS EXCEL SPREADSHEET '
        DoCmd.TransferSpreadsheet acExport, acSpreadsheetTypeExcel12Xml, temp, _
           "C:\Path\To\Output\Folder\" & rst!projectname & "_" & rst!viewname & ".xlsx", _
           True

        rst.MoveNext
    Loop

    rst.Close

    Set rst = Nothing
    Set qdef = Nothing
    Set db = Nothing

    MsgBox "Successfully imported views to local tables and " _
                    & "Excel spreadsheets!", vbInformation

End Sub

资源

• Open Recordset VBA Method
• Oracle Connections Strings
• Creating Pass-Through Query in VBA Code

Answer 2

您已经问了多个问题，所以答案的结构是相应的：

要使用 VBA 创建 MS 访问表，请参考以下示例代码 sn-p：

Public Sub CreateTableVBA() 
    Dim SQL As String 
    SQL = "CREATE TABLE ThisTable " & "(FirstName CHAR, LastName CHAR);" 
    DoCmd.RunSQL SQL 
End Sub

为了创建多个表，您应该有一个表名数组和相应的 SQL 语句数组，如上图所示。然后您可以使用 VBA For-Next 代码块循环遍历数组，运行 DoCmd.RunSQL 命令。

或者，您可以在 VBA Database 对象上使用 Execute() 函数而不是 DoCmd.RunSQL，如下所示：

Sub CreateTableXSQL() 

    Dim dbs As Database 

    ' include the path to MyDb.mdb on your computer. 
    Set dbs = OpenDatabase([Path to MyDb.mdb]) 

    ' create a table SQL with two text fields. 
    dbs.Execute "CREATE TABLE ThisTable " & "(FirstName CHAR, LastName CHAR);" 

    dbs.Close 

End Sub

希望这会有所帮助。