Excel VBA DO循环扫描日期范围并填写缺失的日期

Question

我有一个包含约 20,000 行数据的工作表。每行在 C 列中都有一个交易日期。每个工作表将仅包含上个月的数据。我想要发生的事情是循环遍历每个日期并确保没有丢失日期，如果缺少日期，我需要循环将丢失的日期插入新行。我在网上找到了这个，并尝试将它定制到我的工作表中，但无法让它工作：

 Dim i As Long:  i = 1
 'Adds missing dates as new rows
 Do
 If Cells(i + 1, "C") > Cells(i, "C") + 1 Then
      Rows(i + 1).Insert xlShiftDown
      Cells(i + 1, "C") = Cells(i, "C") + 1
 End If
 i = i + 1
 Loop Until Cells(i + 1, "C") = ""

我有一堆不同的宏，它们将数据格式化为表格，然后按交易日期对其进行排序。我不确定该表是否会产生另一个问题，但我似乎无法让它工作。

非常感谢任何提示！

Answer 1

给使用此代码的任何人的注意事项 - 您必须对日期进行格式化，以便在个位数月份（即 1 月 - 例如“1/1/17”）中，您的月份前面有一个零，使其成为两位数（即 2017 年 1 月 1 日）。除非您这样做，否则代码将不起作用。在excel主页的“更多数据格式”下有一个数据类型，它将在一位数月份前包含零。感谢您的代码，它对我帮助很大！

Answer 2

从如下所示的数据开始：

---

运行此代码以自下而上循环日期并插入缺失的行。

Sub insertMissingDate()
    Dim wks As Worksheet
    Set wks = Worksheets("Sheet1")

    Dim lastRow As Long
    lastRow = wks.Range("C2").End(xlDown).Row

    'Work bottom up since we are inserting new rows
    For i = lastRow To 3 Step -1
        curcell = wks.Cells(i, 3).Value
        prevcell = wks.Cells(i - 1, 3).Value

        'Using a loop here allows us to bridge a gap of multiple missing dates
        Do Until curcell - 1 = prevcell Or curcell = prevcell
            'Insert new row
            wks.Rows(i).Insert xlShiftDown

            'Insert missing date into new row
            curcell = wks.Cells(i + 1, 3) - 1
            wks.Cells(i, 3).Value = curcell
        Loop
    Next i
End Sub

结果：