两种条件下删除行的最有效方法

Question

我要做的是删除电子表格中两个单独列中值为 0 的行，因为这表明该行中没有有用的数据。虽然可以将For loop 与If/Then 条件一起使用，但我发现这非常慢，因为我的数据集有大约51,000 行，而且它实际上需要数小时甚至数天才能运行。

经过一番搜索，我发现了另一种方法，我认为它会更快并且目前正在使用：

Public Sub deleteRows()
     ' source: http://www.ozgrid.com/forum/showthread.php?t=64364
    Dim lastRow As Long
    Dim n As Long
    Dim RT As Date
    RT = Time

    With ActiveSheet
        lastRow = .Cells(.Rows.Count, 2).End(xlUp).Row
    End With

    For n = lastRow To 2 Step -1
        If (Trim(ActiveSheet.Cells(n, 3).Value) = 0) And (Trim(ActiveSheet.Cells(n, 6).Value) = 0) Then
            ActiveSheet.Cells(n, 1).EntireRow.Delete
        End If
    Next n
    MsgBox Format(Time - RT, "hh:mm:ss")
End Sub

但是，我只使用 1000 个单元进行了测试，运行时间为 402 秒，这表明以相同的速率运行所有数据需要 5.584 小时。

有什么方法可以加快这个过程吗？我错过了什么明显的东西吗？

*编辑：此代码作为另一个代码的子部分运行，其中 ScreenUpdating = False 在代码的开头声明。

Answer 1

不，实际上需要更长的时间。如果你删除一行，它下面的每一行都会单独上移，如果你要删除的行下面有更多行，这显然需要更长的时间。

这里有几个简单的方法：

1. 使用 AutoFilter 过滤不需要的行，然后删除可见单元格。

2. 使用自动筛选来筛选要保留的行并将其复制到新工作簿。

3. 首先对值进行排序，以便所有不需要的行都位于底部。你已经从下往上删除了，所以你只需要在你的循环前面插入一个排序。

Answer 2

这是一种使用自动过滤器的方法：

Public Sub deleteRows()
    Dim lastRow As Long
    Dim rng As Range
    Dim start

    start = Timer
    With ActiveSheet
        .AutoFilterMode = False
        lastRow = .Cells(.Rows.Count, 2).End(xlUp).Row
        '~~> Set the range of interest, no need to include the entire data range
        Set rng = .Range("B2:F" & lastRow)
        rng.AutoFilter 2, 0 '~~> filter zeros on C column
        rng.AutoFilter 5, 0 '~~> filter zeros on F column
        '~~> Delete the entire row of the remaining visible cells
        rng.Offset(1, 0).Resize(rng.Rows.Count - 1) _
            .SpecialCells(xlCellTypeVisible).EntireRow.Delete
        .AutoFilterMode = False
    End With
    Debug.Print (Timer - start) * 1000 '~~> in ms
End Sub

对样本数据进行了尝试和测试（单元格 B2：L52802）。
在我的机器上删除需要 11699.22 毫秒或大约 11.7 秒。
与您估计的 5 小时相比，我认为这已经足够快了（具体来说要快 1700 倍）。