【问题标题】:Loop to find 2 strings and copy to a new sheet循环查找 2 个字符串并复制到新工作表
【发布时间】:2020-02-06 18:28:31
【问题描述】:

我是 VBA 的新手,我正在尝试,但卡住了。

我有一张名为“完整历史文件”的表格,其中 A 列中有各种数据。

然后我编写代码来创建称为 Blasted 1 到 Blasted i 的各种工作表

我现在想在工作表完整历史文件的单元格 A1 中使用代码开始来查找字符串 1“BLAST DRIVER ON”,然后查找字符串 2“BLAST DRIVER ON”并复制字符串 1 和字符串 2 之间的所有行 - 1 行到单张 爆破 1

然后它必须循环复制字符串 2 和下一个“BLAST DRIVER ON”之间的数据到工作表 Blasted 1 + i

这必须一直持续到到达空白单元格为止。

我设法让代码工作以复制第一个查找,但不知道如何循环它:

Sub CopyData() 
Dim s As Range, e As Range, i As Long 
i = 1 With Sheets("Full History File") 
Set r = .Range("A:A").Find("BLAST DRIVER ON") 
If Not r Is Nothing Then 
Set e = .Range("A:A").Find("BLAST DRIVER ON", r) 
If Not e Is Nothing Then 
.Range(r, e).EntireRow.Cut Sheets("Blasted 1").Range("A1")
End If 
End If 
End With 
End Sub 

请大家帮忙!

如果需要,这里是我用来创建使用 Google 找到的工作表的代码:

Dim cell As Range
Dim b As String
Dim e As String
Dim s As Integer
Sheets("Blast List").Select
b = "A2" 

e = Range(b).End(xlDown).Address 

For Each cell In Range(b, e)
s = Sheets.Count
Sheets.Add After:=Sheets(s)
Sheets(s + 1).Name = cell.Value
Next cell

感谢您的任何帮助

修订,因为我认为我错误地解释了我需要的内容:

我在工作表“FULL HISTORY FILE”的 A 列中有多行,其中 > 包含文本“BLAST DRIVER ON”和其他一些文本。我正在寻找代码>以查找包含此>文本的第一行(查找 1)和下一行(查找 2)。

然后我希望代码创建一个名为 Blasted 1 的工作表(因为它是找到的文本的第一个>实例)并将 Find 1 和 Find 2 之间的所有行复制到 >新创建的工作表“Blasted 1”

然后我希望代码在 Find 2 之后找到包含文本的下一行 (查找 3)并创建一个名为“Blasted 2”的工作表(找到第二个实例)并将 >Find 2 和 Find 3 之间的行复制到新创建的工作表中。

我希望这能更好地理解

【问题讨论】:

标签: excel vba loops find


【解决方案1】:

也许这会有所帮助。您可以使用 For-Next 循环,就像我在这里使用的那样,或者使用 Alex 建议的 Do 循环。

Sub x()

Dim i As Long, rFind As Range, rFind2 As Range, rFind3 As Range, ws As Worksheet, s As String

s = "BLAST DRIVER ON" 'define search term here so only need to change once if needed

With Sheets("Full History File").Columns(1)
    Set rFind3 = .Find(What:="END HISTORY FILE", LOokat:=xlPart, MatchCase:=False, SearchFormat:=False)
    Set rFind = .Cells(Rows.Count, 1)
    For i = 1 To WorksheetFunction.CountIf(.Cells, "*" & s & "*")         'cycle through number of times text is found
        Set rFind = .Find(What:=s, After:=rFind, LookIn:=xlFormulas, _
                          LOokat:=xlPart, SearchOrder:=xlByRows, _
                          SearchDirection:=xlNext, MatchCase:=False, SearchFormat:=False) 'specify all parameters to be on the safe side
        If Not rFind Is Nothing Then
            Set rFind2 = .Find(What:=s, After:=rFind)                     'find next instance
            Set ws = Worksheets.Add(After:=Sheets(Sheets.Count))          'add new sheet
            ws.Name = "Blasted " & i                                      'name it
            If i = WorksheetFunction.CountIf(.Cells, "*" & s & "*") Then
                Set rFind2 = rFind3.Offset(1)                             'remove .Offset(1) if you don't want "END OF HISTORY FILE" copied
            End If
            Range(rFind, rFind2.Offset(-1)).Copy ws.Range("A1") 'copy intermediate range
        End If
    Next i
End With

End Sub

【讨论】:

  • 您好 SJR,感谢您的协助,但您给我的代码没有任何作用。工作表未创建,信息未从 FULL HISTORY FILE 复制到新创建的工作表。
  • 为我工作。问题可能是找不到文本。也许你需要Lookat:=xlpart - 不知道你的设置很难说。
  • 嗨 SJR,当我删除 For i 语句和 Next i 时,代码将复制到一张“Blasted 0”。我调试了代码并注意到它转到 For i = 1 语句,然后立即转到 End With。你可能知道为什么吗?
  • 正如上面提到的,听起来好像您的单元格不包含该文本,而没有其他任何内容。我做了一些修改,所以再试一次。
  • 嗨,SJR,我发现了另一个障碍,它确实按照我的意愿复制了数据,除了最后一个没有被复制到工作表上的事件。例如...有 24 次我在工作表中找到“BLAST DRIVER ON”,但它只复制到第 23 个事件。另一个问题是我如何将找到的第一个与其余数据一起复制?再次感谢您为我指明了正确的方向
【解决方案2】:

不确定这是否正是您要寻找的,但这是您描述的循环的一个更简单的版本。它不需要在一系列单元格中查找特定值以及两次命中之间的范围。

Sub BLAST()
Application.ScreenUpdating = False
Dim last As Integer, i As Integer, j As Integer, cel As Range
last = Sheets("Sheet1").Range("A" & Rows.Count).End(xlUp).Row
i = 0
j = 2
For Each cel In Sheets("Sheet1").Range("A1:A" & last)
    If cel.Value = "BLAST" Then
        i = i + 1
        j = 2
        Sheets.Add After:=Sheets(Sheets.Count)
        Sheets(Sheets.Count).Name = "Blasted " & i
        Sheets("Blasted " & i).Range("A1") = cel.Value
    Else
        Sheets("Blasted " & i).Range("A" & j) = cel.Value
        j = j + 1
    End If
Next cel
Application.ScreenUpdating = True
End Sub

这只是循环遍历范围内的所有单元格,如果找到条件,单元格值将复制到名称为“Blasted”+下一个数字的新工作表中。然后将每个后续单元格复制到该工作表的下一行,直到找到另一个匹配项。

目前它有点基本,但可以轻松修改以满足您的需求(例如,复制整行而不是值,或者在下一个空白单元格结束而不是 A:A 中使用的完整范围)

【讨论】:

    【解决方案3】:

    这是另一个方法略有不同的示例。它为您的源数据设置范围,然后直接向下走,直到找到一个空白单元格。 Find 和 Copy 方法根本没有用到,只是一个简单的赋值语句。

    Sub CopyBlastedData()
        Dim copiedBlastedWS As Worksheet
        Dim copiedBlastedData As Range
    
        Dim blastedData As Range
        Set blastedData = ThisWorkbook.Sheets("Full History File").Range("A1")
        Do While Not IsEmpty(blastedData)
            If blastedData.Value = "BLAST DRIVER ON" Then
                '--- create a new sheet
                Set copiedBlastedWS = ThisWorkbook.Sheets.Add
                Set copiedBlastedData = copiedBlastedWS.Range("A1")
                copiedBlastedData.Value = blastedData.Value
            Else
                copiedBlastedData.Value = blastedData.Value
            End If
            Set copiedBlastedData = copiedBlastedData.Offset(1, 0)
            Set blastedData = blastedData.Offset(1, 0)
        Loop
    End Sub
    

    【讨论】:

      猜你喜欢
      • 1970-01-01
      • 1970-01-01
      • 2018-08-08
      • 2015-01-12
      • 2020-02-08
      • 2013-06-08
      • 1970-01-01
      • 1970-01-01
      • 1970-01-01
      相关资源
      最近更新 更多