VBA 中的复制粘贴效率和工作表数组

Question

我有以下代码用于在工作表数组中粘贴特定范围的单元格 - 不是全部：

dim ws as Worksheet
dim DecisionWorksheets
dim myPassword as String
dim copyrange
dim wf as WorksheetFunction

Set wf = Application.WorksheetFunction
Set DecisionWorksheets = Sheets(Array("ADMIN", "LM", "CA", "FM", "GD"))
For Each ws In DecisionWorksheets
    ws.Unprotect myPassword
    ws.Cells.ClearContents
Next ws

rownum = wf.Max(Range("B:B"))
copyrange = Worksheets("Data").Range(Cells(4, 2), Cells(rownum + 3, 6)).Copy

For Each ws In DecisionWorksheets
    ws.Range("B7").PasteSpecial xlPasteValues
Next ws

For Each ws In DecisionWorksheets
    ws.Protect myPassword
Next ws

上面数组中的每个工作表都受密码保护，如果我将“ws.Unprotect myPassword”放在我的第二个循环中，剪切复制模式将被禁用。因此，我创建了一个单独的“for each”循环，它首先会通过一组工作表来取消保护它们（第一个循环），然后再次保护它们（第三个循环）。

我的问题是关于我的代码的效率。也就是说，我只是想知道是否有任何方法可以将这三个循环合并为一个循环。 任何其他建议也将不胜感激！

Answer 1

我相信粘贴代码最初对您不起作用，因为您正在清除循环中取消复制模式的工作表单元格。 如果您复制一个范围然后转到另一个工作表并删除单元格，则您不再复制这些单元格。 清除单元格后，您可能需要复制和粘贴。看看这个例子。

Sub Button1_Click()
    Dim ws As Worksheet
    Dim DecisionWorksheets
    Dim myPassword As String
    Dim sh As Worksheet, LstRw As Long, CopyRng As Range

    myPassword = "123"
    Set DecisionWorksheets = Sheets(Array("ADMIN", "LM", "CA", "FM", "GD"))

    Set sh = Sheets("Data")

    With sh
        LstRw = .Cells(.Rows.Count, "A").End(xlUp).Row
        Set CopyRng = .Range(.Cells(4, 2), .Cells(LstRw + 3, 6))
    End With

    Application.ScreenUpdating = 0
    For Each ws In DecisionWorksheets
        ws.Unprotect myPassword
        ws.Cells.ClearContents
        CopyRng.Copy
        ws.Range("B7").PasteSpecial xlPasteValues
        ws.Protect myPassword
    Next ws

End Sub