做直到什么都没找到

Question

我正在研究一个宏来查看股票数据。如果在给定日期没有可用数据，则数据在这些行中显示“-”。我需要删除这些行。 我想出了一个删除找到的第一行的宏。我需要继续执行，直到所有带有“-”的行都被删除。

如何使用 Do Until 循环来做到这一点？

Sub removejank()
'
' removejank Macro
    Cells.Find(What:="-", After:=ActiveCell, LookIn:=xlFormulas2, LookAt:= _
        xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:=False _
        , SearchFormat:=False).Activate
        
    If ActiveCell.Value = "-" Then
        Rows(ActiveCell.Row).Delete
    End If        
End Sub

Answer 1

有许多可能的方法来循环和删除行。

在您的示例中，当您循环数据时，使用 Activate 会显着减慢运行时间。 .Activate 几乎在任何情况下都可以完全避免。显然，我看到你所做的是使用宏记录器，所以它在那里是可以理解的。

不管怎样，试试下面的代码。这仅在 A 列中查找。如果您需要在不同的列中查找，则更改此行中的“1”：

If .Cells(r, 1).Value = "-" Then

到您要查看的列#。此外，您可能需要更改此行中的工作表名称：

With ThisWorkbook.Worksheets("Sheet3")

匹配您希望代码在其中运行的工作表名称。

---

因此，许多方法中的这种方法的工作方式是，您将使用For r = 1 ... 遍历 A 列中的每一行。您正在查看单元格值的每个循环迭代。如果它等于-，那么If 语句为真并继续将单元格添加到我们命名为delRng 的特殊区域中。您实际上还没有删除该行，只是在此范围内跟踪它们。

完成后，您将获取delRng 中的所有单个单元格，并使用.EntireRow 属性一次将它们全部删除。这通常比一次删除一行要快。

Public Sub RemoveJunk()

    Dim delRng As Range, r As Long
    With ThisWorkbook.Worksheets("Sheet3")
        For r = 1 To .Cells(.Rows.Count, 1).End(xlUp).Row
            If .Cells(r, 1).Value = "-" Then
                If delRng Is Nothing Then
                    Set delRng = .Cells(r, 1)
                Else
                    Set delRng = Union(delRng, .Cells(r, 1))
                End If
            End If
        Next r
    End With
    
    If Not delRng Is Nothing Then delRng.EntireRow.Delete

End Sub