F# 在实际处理 int64 时假设为 int

Question

通过 Project Euler 尝试学习 F#，我在为 problem 3 编写解决方案时偶然发现了一个类型推断问题。

这是我写的：

let rec findLargestPrimeFactor p n = 
    if n = 1 then p
    else
        if n % p = 0 then findLargestPrimeFactor p (n/p)
        else findLargestPrimeFactor (p+1) n

let result = findLargestPrimeFactor 2 600851475143L

但是，编译器给了我以下错误：

错误 FS0001：此表达式应为 int 类型，但此处为 int64 类型

由于我希望 findLargestPrimeFactor 中使用的类型是从使用中推断出来的，我很惊讶地发现编译器似乎假设参数 n 是一个 int，因为在唯一调用函数时完成使用 int64。

谁能给我解释一下：

1. 为什么编译器似乎对类型感到困惑
2. 如何解决此限制

Answer 1

findLargestPrimeFactor 中的类型是根据使用情况推断出来的。 F#编译器以自上而下的方式进行类型推断，因此p和n的类型（findLargestPrimeFactor的参数）是根据它们在函数中的使用情况推断出来的。当编译器看到let result = ... 时，参数类型已经被推断为int。

最简单的解决方案是在所有常量值上使用L 后缀，因此类型将被推断为int64：

let rec findLargestPrimeFactor p n = 
    if n = 1L then p
    else
        if n % p = 0L then findLargestPrimeFactor p (n/p)
        else findLargestPrimeFactor (p + 1L) n

let result = findLargestPrimeFactor 2L 600851475143L

如果您想要更高级的解决方案，您可以使用LanguagePrimitives 模块中的通用一和零常量。这允许findLargestPrimeFactor 是通用的（-ish），因此可以更轻松地与不同的数字类型重用：

open LanguagePrimitives

let rec findLargestPrimeFactor p n = 
    if n = GenericOne then p
    else
        if n % p = GenericZero then findLargestPrimeFactor p (n/p)
        else findLargestPrimeFactor (p + GenericOne) n

(* You can use one of these, but not both at the same time --
   now the types of the _arguments_ are used to infer the types
   of 'p' and 'n'. *)

//let result = findLargestPrimeFactor 2L 600851475143L
let result = findLargestPrimeFactor 2 Int32.MaxValue

根据@kvb 的建议，以下是通用编写此函数的方法：

open LanguagePrimitives

let inline findLargestPrimeFactor p n =
    let rec findLargestPrimeFactor p n =
        if n = GenericOne then p
        else
            if n % p = GenericZero then findLargestPrimeFactor p (n/p)
            else findLargestPrimeFactor (p + GenericOne) n
    findLargestPrimeFactor p n

(* Now you can call the function with different argument types
   as long as the generic constraints are satisfied. *)
let result = findLargestPrimeFactor 2L 600851475143L
let result' = findLargestPrimeFactor 2 Int32.MaxValue