GNU 链接器脚本 - 将闪存移动到新区域

Question

我正在尝试使用 STM32F446ZE 微控制器的链接器脚本来移动内存部分。我最初的设置是这样的：

MEMORY
{
RAM (xrw)      : ORIGIN = 0x20000000, LENGTH = 128K
FLASH (rx)      : ORIGIN = 0x8000000, LENGTH = 512K - 128k
DATA (rwx)      : ORIGIN = 0x08060000, LENGTH = 5120
}

SECTIONS
{
  .user_data :
  {
    . = ALIGN(4);
    KEEP(*(.user_data))
    . = ALIGN(4);
  } >DATA
  .isr_vector :
  {
    . = ALIGN(4);
    KEEP(*(.isr_vector)) /* Startup code */
    . = ALIGN(4);
  } >FLASH

  .text :
  {
    . = ALIGN(4);
    *(.text)           /* .text sections (code) */
    *(.text*)          /* .text* sections (code) */
    *(.glue_7)         /* glue arm to thumb code */
    *(.glue_7t)        /* glue thumb to arm code */
    *(.eh_frame)
    KEEP (*(.init))
    KEEP (*(.fini))
    . = ALIGN(4);
    _etext = .;        /* define a global symbols at end of code */
  } >FLASH

  .rodata :
  {
    . = ALIGN(4);
    *(.rodata)         /* .rodata sections (constants, strings, etc.) */
    *(.rodata*)        /* .rodata* sections (constants, strings, etc.) */
    . = ALIGN(4);
  } >FLASH

  .data : 
  {
    . = ALIGN(4);
    _sdata = .;        /* create a global symbol at data start */
    *(.data)           /* .data sections */
    *(.data*)          /* .data* sections */
    . = ALIGN(4);
    _edata = .;        /* define a global symbol at data end */
  } >RAM AT> FLASH

  . = ALIGN(4);
  .bss :
  {
    /* This is used by the startup in order to initialize the .bss secion */
    _sbss = .;         /* define a global symbol at bss start */
    __bss_start__ = _sbss;
    *(.bss)
    *(.bss*)
    *(COMMON)
    . = ALIGN(4);
    _ebss = .;         /* define a global symbol at bss end */
    __bss_end__ = _ebss;
  } >RAM

  /* User_heap_stack section, used to check that there is enough RAM left */
  ._user_heap_stack :
  {
    . = ALIGN(4);
    PROVIDE ( end = . );
    PROVIDE ( _end = . );
    . = . + _Min_Heap_Size;
    . = . + _Min_Stack_Size;
    . = ALIGN(4);
  } >RAM

我想要做的是将 DATA 移动到从 0x08000000（闪存当前正在启动的位置）开始，并在 0x08040000（在 DATA 之后）启动 FLASH。我可以很容易地在内存部分更改它，但是我的程序无法启动。我相信 SECTIONS 块中的某些代码可能必须更改，但我不确定如何更改。问题是：如何将闪存（程序代码所在的位置）移动到以后的内存地址。

Answer 1

How can I change the start address on flash? 如果你有 stmf7 这将适用，遗憾的是你没有从你喜欢的任何地址启动的功能。您有固定数量的选项。

查看数据表，7.1.2 复位：RESET 服务程序向量固定在内存映射中的地址 0x0000_0004。这意味着闪存中的第二个 4 个字节是复位处理程序的地址。

但是，您可以使用 BOOT 引脚更改启动的位置，再次参考 2.4 版的数据表 STM32F4xx 微控制器实现了一种特殊机制，能够从其他存储器（如内部SRAM）。

因此，您唯一的选择是更改用于引导的内存类型。但在你的情况下，它根本没有帮助。

Answer 2

正如 P__J__ 提到的，您不能将整个数据区域移动到地址 0x0800 0000，因为 MCU 期望中断向量从那里开始。当 MCU 从闪存启动时，地址0x0800 0000 映射到地址0x0000 0000。 您可以做的是为向量表的长度创建另一个区域，并根据需要移动部分的其他部分。

MEMORY
{
RAM (xrw)       : ORIGIN = 0x20000000, LENGTH = 128K
VECTORS (rx)    : ORIGIN = 0x08000000, LENGTH = 0xB8
FLASH (rx)      : ORIGIN = 0x080000B8, LENGTH = 512K - 128k - 0xB8
DATA (rwx)      : ORIGIN = 0x08060000, LENGTH = 5120
}

  .isr_vector :
  {
    KEEP(*(.isr_vector))
  } > VECTORS

Answer 3

这是不可能的，因为您的 STM32 uC 从闪存启动时从地址 0x8000000 开始。

问题是：如何将闪存（程序代码所在的位置）移动到以后的内存地址。

答案：不可能。从 FLASH 启动时，向量表必须从 0x8000000 开始