用 Perl 检测空目录

Question

在 perl 中测试文件夹是否为空的简单方法是什么？ -s 和 -z 不起作用。

例子：

#Ensure Apps directory exists on the test PC.
if ( ! -s $gAppsDir )
{ 
    die "\n$gAppsDir is not accessible or does not exist.\n"; 
}

#Ensure Apps directory exists on the test PC.
if ( ! -z $gAppsDir )
{ 
    die "\n$gAppsDir is not accessible or does not exist.\n"; 
}

上面这些，不能正常告诉我文件夹是空的。谢谢！

---

谢谢大家！我最终使用了：

sub is_folder_empty { my $dirname = shift; opendir(my $dh, $dirname) or die "Not a directory"; 
return scalar(grep { $_ ne "." && $_ ne ".." } readdir($dh)) == 0; }

Answer 1

为了清楚起见，有点冗长，但是：

sub is_folder_empty {
    my $dirname = shift;
    opendir(my $dh, $dirname) or die "Not a directory";
    return scalar(grep { $_ ne "." && $_ ne ".." } readdir($dh)) == 0;
}

那么你可以这样做：

if (is_folder_empty($your_dir)) {
    ....
}

Answer 2

使用grep { ! /^[.][.]?\z/ } readdir $dir_h 可能会影响性能，以防检查执行多次并且某些目录可能有很多文件。

最好在找到. 或.. 以外的目录条目时短路。

在带有 ActiveState perl 5.10.1 的 Windows XP 上，以下 sub 似乎比我的 $HOME 上的 grep 方法快两倍：

sub is_dir_empty {
    my ($dir) = @_;

    opendir my $h, $dir
        or die "Cannot open directory: '$dir': $!";

    while ( defined (my $entry = readdir $h) ) {
        return unless $entry =~ /^[.][.]?\z/;
    }

    return 1;
}

Answer 3

或者没有任何 grepping 或正则表达式 - 这排除了任何奇怪的文件名意外获得的机会。另外，我的测试速度稍快。

#!/usr/bin/perl
use strict;
use warnings;

sub is_dir_empty {
    return -1 if not -e $_[0];   # does not exist
    return -2 if not -d $_[0];   # in not a directory
    opendir my $dir, $_[0] or    # likely a permissions issue
        die "Can't opendir '".$_[0]."', because: $!\n";
    readdir $dir;
    readdir $dir;
    return 0 if( readdir $dir ); # 3rd times a charm
    return 1;
}

my @folders = qw( ./ ./empty ./hasonefile ./hastwofiles ./doesnotexist ./afile );
for my $folder ( @folders ) {
    print "Folder '$folder' ";
    my $rc = is_dir_empty( $folder );
    if( $rc == -1 ) {
        print "does not exist\n";
    } elsif( $rc == -2 ) {
        print "is not a directory\n";
    } elsif( !$rc ) {
        print "is not empty\n";
    } else {
        print "is empty\n";
    }
}

很简单。如果您从对 readdir 的调用中获得三个有效响应，那么您就知道其中一定有一个文件。无论文件可能具有什么名称 - 或处理文件的顺序。会更喜欢名为“is_dir_used”的东西，因为我个人不喜欢双负函数名称和返回值。

Answer 4

还有来自 cpan 的File::List。在这里有点过分了，但是对于稍微复杂的请求来说可以很方便，比如测试一个目录是否为空，这意味着它只包含空目录（即：不是文件）。

Answer 5

opendir(DIR,"DIR PATH") or die "Unable to open directory \"DIR PATH\" \n";
my @drList = readdir(DIR);
close(DIR);
if( grep(/\w/,@drList) ){ print "Not Empty\n" }
else { print "Empty\n" }

Answer 6

  sub is_folder_empty {
        my $dirname = shift;
        my @files = File::Find::Rule->file()->name('*')->maxdepth(1)->in("$dirname");
        return $#files < 0;
    }

Answer 7

Credit to DevShed

if (scalar <directory/*>) {print qq|File Exists\n|}

---

编辑

要包含隐藏文件：

@arr = <directory/* directory/.*>;
@arr = grep {!/^directory/[.]{1,2}$/} @arr;
if (@arr) { print qq|File or Directory Exists\n| }

---

请阅读 cmets，因为有很好的观点。尽管这个答案得到了否定的分数，但它仍然是正确的。