Excel VBA 删除行 - 如何更快？

Question

我目前正在使用我在 stackxchg 上找到的以下代码 sn-p 来删除 A 列中没有数值的行。这可行，但是对于 5000 行的工作表来说速度非常慢。有什么办法可以让这件事走得更快吗？这个概念是，我有一些行只有在满足条件时才会踢出日期，并且将使用此列中的日期生成图表。我希望图表范围参考随行而变化，但这很难，因为行中一直有公式（并且要使图表看起来不错，行需要完全为空）。我的解决方法是找到一个可以删除这些行的宏（但使用此代码太慢了）。任何帮助，将不胜感激。

Sub Sample()
Dim LR3 As Long, i3 As Long

With Sheets("Basket Performance")
    LR3 = .Range("A" & .Rows.Count).End(xlUp).Row

    For i3 = LR3 To 2 Step -1
        If Not IsNumeric(.Range("A" & i3).Value) Or _
        .Range("A" & i3).Value = "" Then .Rows(i3).Delete
    Next i3
End With

结束子

Answer 1

您可以在循环结束时执行一次删除：

Sub Sample()

    Dim LR3 As Long, i3 As Long, rng As Range

    With Sheets("Basket Performance")
        LR3 = .Range("A" & .Rows.Count).End(xlUp).Row

        For i3 = LR3 To 2 Step -1
            If Not IsNumeric(.Range("A" & i3).Value) Or _
                           .Range("A" & i3).Value = "" Then 
                If rng Is Nothing Then
                    Set rng = .Cells(i3, 1)
                Else
                    Set rng = application.union(rng, .Cells(i3, 1))
                End If
            End If '<<EDIT
        Next i3
    End With

    If Not rng Is Nothing then rng.Entirerow.Delete

End Sub

Answer 2

你可以试试这个

Option Explicit

Sub delrow()

With ThisWorkbook.Worksheets("Basket Performance")
    .Columns("A").Insert '<== insert a "helper" column for counting and sorting purposes. it'll be removed by the end of the macro
    .Columns("B").SpecialCells(xlCellTypeConstants, xlNumbers).Offset(, -1).FormulaR1C1 = "=COUNT(R1C[1]:RC[1])"
    .Cells.Sort key1:=.Columns("A"), order1:=xlAscending, Orientation:=xlTopToBottom, Header:=xlNo
    .Columns("A").Cells.SpecialCells(xlCellTypeBlanks).EntireRow.Delete '<== maybe you don't need to delete but just define the chart range reference from row 1 down to the last row in column A with a number
    .Columns("A").Delete '<== remove the "helper" column
End With

End Sub

您可能要考虑在整理后不要删除“非数字”行，而只需使用数字定义从第 1 行到 A 列最后一行的图表范围参考