如何避免 <defunct> 进程？

Question

我从主控主机到从属主机进行 ZFS 远程复制，我有一个在主控主机上运行的 Perl 脚本。

对于每个文件系统，它 ssh 到远程主机并以侦听模式启动 mbuffer，然后脚本继续，然后发送数据。成功时，mbuffer 应自行退出。

问题

在远程主机上通过 ssh 启动 mbuffer 并在脚本中继续运行非常困难。我最终做了你在下面看到的。

问题在于，在脚本退出之前，它会为每个文件系统留下一个 <defunct> 进程。

问题

可以避免<defunct> 进程吗？

sub mbuffer {
    my ($id, $zfsPath) = @_;

    my $m = join(' ', $mbuffer, '-I', $::c{port});
    my $z = join(' ', $zfs, 'receive', , $zfsPath);
    my $c = shellQuote($ssh, $::c{slaves}{$id}, join('|', $m, $z));

    my $pm = Parallel::ForkManager->new(1);
    my $pid = $pm->start;
    if (!$pid) {
        no warnings;  # fixes "exec" not working
        exec($c);
        $pm->finish;
    }

    sleep 3; # wait for mbuffer to listen

    return $pid;
}

Answer 1

当你创建一个进程时，它会一直存在，直到它的父进程获得它。 （如果它的父进程先退出，它将自动获取。）进程可以使用wait 或waitpid 来获取它的子进程。它还可以通过在创建子节点之前使用local $SIG{CHLD} = 'IGNORE'; 导致其子节点被自动收割。

---

请注意，Parallel::ForkManager 不是启动单个子项的正确工具。产生一个工人不是它的目的。

use String::ShellQuote qw( shell_quote );

sub mbuffer {
    my ($id, $zfsPath) = @_;

    my $mbuffer_cmd = shell_quote($mbuffer, '-I', $::c{port});
    my $zfs_cmd     = shell_quote($zfs, 'receive', $zfsPath);
    my $remote_cmd  = "$mbuffer_cmd | $zfs_cmd";
    my $local_cmd   = shell_quote($ssh, $::c{slaves}{$id}, $remote_cmd);

    # open3 will close this handle.
    # open3 doesn't deal well with lexical handles.
    open(local *CHILD_STDIN, '<', '/dev/null') or die $!;    

    return open3('<&CHILD_STDIN', '>&STDOUT', '>&STDERR', $local_cmd);
}

IPC::Open3 的级别很低，但它最接近您现有的代码。启动进程的更好方法包括 IPC::Run3 和 IPC::Run。

Answer 2

一方面，没有理由在一个进程中使用P::FM。此外，这也是不利的，因为您放弃了对流程管理的更精细控制。

但是这里的直接错误在于exec的使用；这篇文章只解决了这个问题。

exec 调用将进程中的内容替换为另一个程序，并且永远不会返回。因此，exec 之后的子代码不会运行（请参阅文档）。因此$pm->finish 被挂起，子进程永远不会被收割，并且操作系统将其信息保存在进程表中，因此存在已失效/僵尸。

这是直接使用exec 启动另一个程序的基本方法

my $cmd = '...';

my $pid = fork  // die "Can't fork: $!";

if ($pid == 0) {
    exec $cmd;
    die "exec shouldn't return: $!";
}
my $gone = waitpid $pid, 0;

if    ($gone > 0) { say "Child $gone exited with $?" }
elsif ($gone < 0) { say "No $pid process ($gone), reaped already?" }
else              { say "Process $pid still running?" }

在这里，子级从父级继承标准流。此外，在某些情况下，错误报告很粗略（不精确），请参阅 cmets，感谢 ikegami。

ikegami 的answer 可以更详细、更忠实地替代您所做的工作。