从范围 VBA 中查找最后一个单元格

Question

如何从定义的范围中找到最后一个单元格的位置？单元格不必包含任何数据，但必须位于某个 Range 中最右侧和最下方的单元格。

Set rngOrigin = wksOrigin.Cells(IntFirstRow, IntFirstColumn).CurrentRegion

我希望收到

Cells(i,j)

Answer 1

您可以尝试以下方法，但它依赖于始终填充单元格

rngOrigin.End(xlDown).End(xlRight)

或者您可以使用CurrentRegion 并计算行数和列数并使用Offset

或者，您可以使用这种结构，它甚至适用于基于整行或整列的范围。

Sub Test()
    Dim rngOrigin As Excel.Range
    Set rngOrigin = Range("$A$1:$D$6")

    Dim rngLast As Excel.Range
    Set rngLast = rngOrigin.Cells(rngOrigin.Cells.Count)
    Debug.Print rngLast.Address
End Sub

最后，对于具有多个区域的范围，您必须针对范围的 Areas 集合编写脚本...

Sub Test()
    Dim rngOrigin As Excel.Range
    Set rngOrigin = Range("$A$1:$D$6,$F$1:$G$6")
    
    Debug.Print rngOrigin.Areas(1).Cells(rngOrigin.Areas(1).Cells.Count).Address
    Debug.Print rngOrigin.Areas(2).Cells(rngOrigin.Areas(2).Cells.Count).Address

End Sub

Answer 2

使用此代码查找给定范围内的最后一个单元格

Sub GetLastCellFromRange()
    Dim rng As Range

    Set rng = Range("$C$10:$E$20")

    'Set rng = Range(Selection.Address) ' Use this line to select the range in worksheet

    MsgBox "Last Cell of given range is : " & rng.Cells(rng.Rows.Count, rng.Columns.Count).Address
End Sub

希望对你有帮助

Answer 3

如果你想要定义范围的绝对最后一个单元格，不管它是否有任何内容，这里有一个简单的解决方案

Dim InputRng As Range    'define a range for the test'
Set InputRng = Range("$F$3:$F$15") 
MsgBox InputRng(1).Address & ":" & InputRng(InputRng.Cells.Count).Address    'This would output the absolute address of defined range' 

Answer 4

也许这就是你想要的：

Dim rngLastCell As Range
Set rngLastCell = rngOrigin(rngOrigin.Count)

Answer 5

其他人给出的答案大多有效，但如果该区域是非连续单元的联合体，则无效。这是一个适用于单区域和多区域（连续和非连续区域）的版本。

Function LastCellOfRange(rng As Excel.Range) As Excel.Range
  Dim area As Excel.Range
  Dim rowNum As Long
  Dim maxRow As Long
  Dim colNum As Long
  Dim maxCol As Long
  Dim areaIdx As Integer

  Set LastCellOfRange = Nothing

  maxRow = 0
  maxCol = 0
  For areaIdx = 1 To rng.Areas.Count
    Set area = rng.Areas(areaIdx)
    rowNum = area.Cells(area.Cells.Count).row
    If (rowNum > maxRow) Then
      maxRow = rowNum
    End If
    colNum = area.Cells(area.Cells.Count).Column
    If (colNum > maxCol) Then
      maxCol = colNum
    End If
  Next areaIdx

  Set LastCellOfRange = rng.Worksheet.Cells(maxRow, maxCol)
  Set area = Nothing
End Function

Answer 6

我在下面的代码中处理了它，但你的评论很有帮助。谢谢。

intLastRow = rngOrigin.Cells(1, 1).Row + rngOrigin.Rows.Count - 1
intLastCol = rngOrigin.Cells(1, 1).Column + rngOrigin.Columns.Count - 1

Answer 7

也许你在追求这个：

'absolute indexes from cell A1
With rngOrigin
    i = .Rows(.Rows.count).row
    j = .Columns(.Columns.count).Column
End With

'relative indexes from rngOrigin upleftmost cell
With rngOrigin
    i = .Rows(.Rows.count).row - .Rows(1).row + 1
    j = .Columns(.Columns.count).Column - .Columns(1).Column + 1
End With

Answer 8

在您的情况下，由于您想在wksOrigin（定义为工作表）中找到最右侧和最下方的单元格，您可以使用SpecialCells(xlCellTypeLastCell) 来获取最后一个单元格的行和列。

i = wksOrigin.Cells.SpecialCells(xlCellTypeLastCell).Row ' <-- get last row number
j = wksOrigin.Cells.SpecialCells(xlCellTypeLastCell).Column ' <-- get last column number

如果你想调试你的结果，你可以添加：

MsgBox "Last row at " & i & ", last column at " & j