TListView 滚动事件

Question

TListView 控件是否有一个在控件滚动时触发的事件？

我宁愿不必对 TListView 控件进行子类化。

Answer 1

这很有效，但可能会违反您问题的限制。

在包含使用TListView 的表单的单元的interface 部分（在TForm 声明之前），添加

type
  TListView = class(ComCtrls.TListView)
  protected
    procedure WndProc(var Message: TMessage); override;
  end;

然后，在同一单元的implementation部分，定义

procedure TListView.WndProc(var Message: TMessage);
begin
  inherited;
  case Message.Msg of
    WM_HSCROLL, WM_VSCROLL: beep;
  end;
end;

Answer 2

您可以在不编写后代类的情况下对窗口进行子类化，这在您期望更改的行为是一次性要求时很有用。像Andreas's answer 一样编写TWndMethod 函数，但可以将它写在你想要的任何类中，例如拥有列表视图的表单。将其分配给列表视图控件的WindowProc 属性。在执行此操作之前，请存储该属性的先前值，以便您可以将所有其他消息推迟到它。

type
  TNanikForm = class(TForm)
    ListView: TListView;
  private
    FPrevListViewProc: TWndMethod;
    procedure ListViewWndProc(var Msg: TMessage);
  public
    procedure Loaded; override;
  end;

procedure TNanikForm.ListViewWndProc(var Msg: TMessage);
begin
  case Msg.Message of
    wm_VScroll: ;
    else FPrevListViewProc(Msg);
  end;
end;

procedure TNanikForm.Loaded;
begin
  inherited;
  FPrevListViewProc := ListView.WindowProc;
  ListView.WindowProc := ListViewWndProc;
end;

Answer 3

或者如果你只想捕获垂直滚动事件，你可以使用它。代码与 Andreas 发布的几乎相同...

type
  TListView = class(ComCtrls.TListView)
  protected
    procedure WMVScroll(var Message: TWMVScroll); message WM_VSCROLL;
  end;

procedure TListView.WMVScroll(var Message: TWMVScroll);
begin
  inherited;
  Beep;
end;

Answer 4

所有答案都很好:-)，但我不会创建新的班级孩子。 感谢大家的帮助 :-)！

---

我的解决方案： 我使用组件（在 Delphi 7 中）ApplicationEvents 并检查 ScrollBar 位置 的变化（GetScrollPos(ListView.Handle, SB_VERT))。