因变量的 OpenMP

Question

这是我第一次使用 OpenMP，并将其应用于 Fortran。我碰巧在调整循环时遇到问题，其中有一个变量需要从其先前的值进行更新。我尝试使用 PRIVATE 子句，但结果与串行计算（没有 OpenMP）产生的结果相差甚远。

我在OpenMP website 的某个地方查看了一个使用!$OMP PARALLEL DO ORDERED 的解决方案，该解决方案最终有效（产生与串行解决方案相同的结果）。但似乎使用这个，计算速度比只使用PRIVATE子句要慢很多。

有没有其他方法可以在这种情况下应用 OpenMP 以获得最大速度？

使用ORDERED 选项的代码。

!$OMP PARALLEL DO ORDERED PRIVATE(i,j)
do i = ca,cb
    incre(i) = 0.0d0
    value = 17.0d0*li(i)
    do j = cx,cy
        qx    = hi(i) - hj(j)
        mij   = dsqrt(qx)
        if( mij <= value ) then
            beta   = li(i)*li(j)
            !$OMP ORDERED
            incre(i) = incre(i) + beta
            !$OMP END ORDERED
        end if
    end do
end do
!$OMP END PARALLEL DO

仅使用 PRIVATE 子句的代码

!$OMP PARALLEL DO PRIVATE(i,j,incre,value,beta)
do i = ca,cb
    incre(i) = 0.0d0
    value = 17.0d0*li(i)
    do j = cx,cy
        qx    = hi(i) - hj(j)
        mij   = dsqrt(qx)
        if( mij <= value ) then
            beta   = li(i)*li(j)
            incre(i) = incre(i) + beta
        end if
    end do
end do
!$OMP END PARALLEL DO

Answer 1

正如 Francois 在他的 cmets 中指出的那样，qx 和 mij 需要是线程私有的：

!$OMP PARALLEL DO PRIVATE(i,j,value,beta,qx,mij)
do i = ca,cb
    incre(i) = 0.0d0
    value = 17.0d0*li(i)
    do j = cx,cy
        qx    = hi(i) - hj(j)
        mij   = dsqrt(qx)
        if( mij <= value ) then
            beta   = li(i)*li(j)
            incre(i) = incre(i) + beta
        end if
    end do
end do
!$OMP END PARALLEL DO

incre 不需要是私有的，因为只能通过索引i 访问它。所以所有线程都访问它的不同部分。但是，如果您之后需要访问这些元素，请确保它是公开的（共享的）。