具有假定形状的虚拟参数的过程必须具有显式接口

Question

我对 Fortran 90 完全陌生，我正在尝试了解如何将数组传递给函数。我在网上看了看，找不到任何清晰简单的例子，所以我决定在这里发布。

我希望函数能够处理任意长度的数组（数组的长度不应该是函数的参数之一）。

我尝试编写一个简单的函数示例，该函数返回数组元素的总和：

function mysum(arr)
    implicit none
    real, dimension(:), intent(in) :: arr
    real :: mysum
    integer :: i,arrsize
    arrsize = size(arr)
    mysum=0.0
    do i=1,arrsize
        mysum=mysum+arr(i)
    enddo
end function mysum

program test
    implicit none
    real, dimension(4) :: a
    real :: mysum,a_sum
    call random_number(a)
    print *,a
    a_sum=mysum(a)
    print *,a_sum
end program

当我尝试编译时，我收到以下错误：

array_test.f90:17.14:

 real mysum,a_sum
           1
Error: Procedure 'mysum' at (1) with assumed-shape dummy argument 'arr' must have an explicit interface

我的程序有什么问题？

Answer 1

假定的形状虚拟参数（带有(:) 的参数）需要显式接口 才能在调用站点上使用该过程。这意味着调用代码必须知道子例程标题的确切外观。另见Module calling an external procedure with implicit interface

可以通过多种方式提供显式接口

1。 首选 - 一个模块过程

module procedures
  implicit none

contains

  function mysum(arr)

    real, dimension(:), intent(in) :: arr
    real :: mysum
    integer :: i,arrsize
    arrsize = size(arr)
    mysum=0.0
    do i=1,arrsize
        mysum=mysum+arr(i)
    enddo
  end function mysum
end module

program test
    use procedures

    implicit none
    !no mysum declared here, it comes from the module
    ...
end program

2。 内部过程 - 仅适用于简短的简单过程或如果该过程需要访问主机的变量。由于访问主机变量，它很容易出错。

program test
    implicit none
    !no a_sum declared here, it is visible below contains
    ...    
contains

  function mysum(arr)

    !implicit none inherited from the program

    real, dimension(:), intent(in) :: arr
    real :: mysum
    integer :: i,arrsize
    arrsize = size(arr)
    mysum=0.0
    do i=1,arrsize
        mysum=mysum+arr(i)
    enddo
  end function mysum
end program

3。 界面块 - 完全不推荐，你应该有一些特殊的理由来使用它

function mysum(arr)
  ! removed to save space
end function mysum

program test
    implicit none

     interface
       function mysum(arr)
         real, dimension(:), intent(in) :: arr
         real :: mysum
       end function
     end interface

     !no mysum declared there
     !it is declared in the interface block
     ...
end program