从事件查看器导出服务器日志文件并保存到文件夹中而不覆盖文件

Question

我想从事件查看器中导出服务器日志文件并保存到一个文件夹中而不覆盖该文件。

然后我将通过使用任务计划来设置一个计划来触发这个批处理文件进行自动定期更新。 （我是wevtuitil 和cmd 命令的新手）

例子：

application_event1.evtx
application_event2.evtx
application_event3.evtx
application_event4.evtx

这是我的 bat 文件脚本

//我将从事件查看器中导出日志文件

wevtutil epl Application E:\a\testing_application.evtx

跟随脚本使evtx文件名增加个数

@echo off
setlocal enableextensions enabledelayedexpansion
set "source=E:\a"
if exist "%source%\*.evtx" (
set  increase=0
set  increase=!increase!+1
ren "%source%\*.evtx" "*.!increase!.evtx"
)
endlocal

结果：testing_application.0+1,testing_application.0+1.0+1

Answer 1

set 中缺少 /a，因为它是算术运算。更多信息请输入set /?

你也错过了for-loop。更多请输入for /?

试试这样的。

@echo off
setlocal enableextensions enabledelayedexpansion
set "source=E:\a"

set increase=
for /f "delims=" %%a in ('dir /b /a-d "%source%\*.evtx"') do (
    set /a increase+=1
    echo ren "%%~a" "%%~na!increase!%%~xa"
)
endlocal

我认为你试图实现的目标似乎完全错了。

这里是另一个尝试：

@echo off

set "source=E:\a"
set "filename=testing_application"
wevtutil epl Application E:\a\testing_application.evtx

for /f "tokens=2 delims=-." %%a in (
  'dir /b "%source%\%filename%*.evtx" ^|sort /r ^|findstr /r [0-9]') do ( 
   set "num=%%a"
   goto done
)

ren "%source%\%filename%.evtx"  "%filename%-001.evtx"
exit /b 0

:done
rem :: remove zeros in front of numbers before incrementing
for /f "tokens=* delims=0" %%a in ("%num%") do set num=%%a

set /a num+=1
set incr=000%num%

ren "%source%\%filename%.evtx"  "%filename%-%incr:~-3%.evtx"

exit /b 0

前面零递增数字的解决方案是基于this

前面需要哪些零才能正确sort 文件。