在 clojure 中，如何从另一个宏评估宏的参数？

Question

我有两个宏。第一个将符号作为唯一参数（因为它被传递给 def，它需要一个符号）。第二个函数需要一个符号列表，并且应该单独调用第一个符号和每个符号。

(defmacro m1 [s]
  '(let [f# ... dynamic function definition ...]
      (def ~s f#))

第二个宏应该获取一个符号列表并将它们传递给第一个，但我无法让它工作。我能想到的最好的方法如下：

(defmacro m2 [symbols]
   `(for [s# ~symbols] (eval (read-string (str "(name.of.current.namespace/m1 " s# ")")))))

这会强制 s# 在传递给第一个宏之前对其进行评估。它也被一个字符串列表调用，而不是一个符号列表。

这对于我正在使用的库很有用，该库中的所有函数都采用相同的两个第一个参数。我正在尝试在我的命名空间中为一些函数创建包装函数，这些函数会自动提供前两个参数值，它们都是通用的。

有什么改进的方法吗？

Answer 1

通常当你问如何让两个宏协同工作时，答案是不要让它们都成为宏。我认为我在macro-writing macros 上的博客文章将有助于澄清。对于这种特殊情况，我可能会结合 cmets 的两个建议：

(defmacro build-simpler-functions [& names]
  (cons 'do
        (for [name names]
          `(def ~(symbol (str "simple-" name))
             (partial ~name 5 10))))) ; if you always pass 5 and 10

(build-simpler-functions f1 f2)

这扩展为

(do
  (def simple-f1 (clojure.core/partial f1 5 10))
  (def simple-f2 (clojure.core/partial f2 5 10)))

这看起来基本上是你想要的。

编辑：如果你“总是”传递的参数对于每个函数都不同，你可以这样做：

(defmacro build-simpler-functions [& names]
  (cons 'do
        (for [[name & args] names]
          `(def ~(symbol (str "simple-" name))
             (partial ~name ~@args)))))

(build-simpler-functions [f1 5 10] [f2 "Yo dawg"]) ; expansion similar to the previous