如何调整 Word 文档中的图像大小？答案

【问题标题】：How to resize an image in a Word document?如何调整 Word 文档中的图像大小？
【发布时间】：2021-06-25 23:34:21
【问题描述】：

在 Excel 中，打开 Word 文档，将图像粘贴到当前位置，然后调整大小。

我尝试在InlineShapes.AddPicture 末尾使用高度命令。

这是插入图片的代码。

Sub CreateWordDocWithPicture()
    Dim wdApp As Word.Application
    Dim wdDoc As Word.Document
    DocDirectory = "C:\Documents\"
    Set wdApp = CreateObject("Word.Application") 'Create an instance of word
    Set wdDoc = wdApp.Documents.Open(DocDirectory & "Template.docx", ReadOnly:=True) 
    'Open word file
    wdApp.Visible = True
    wdApp.Selection.InlineShapes.AddPicture Filename:=DocDirectory & "Image.jpg", LinkToFile:=False, SaveWithDocument:=True
        
End Sub

【问题讨论】：

标签： excel vba image ms-word resize

【解决方案1】：

例如：

Sub CreateWordDocWithPicture()
Dim wdApp As New Word.Application, wdDoc As Word.Document, wdIshp As Word.InlineShape
Const DocDirectory As String = "C:\Documents\"
With wdApp
  .Visible = True
  'Open word file
  Set wdDoc = .Documents.Open(DocDirectory & "Template.docx", ReadOnly:=True)
  With wdDoc
    'Insert the image
    Set wdIshp = .InlineShapes.AddPicture(FileName:=DocDirectory & "Image.jpg", _
      LinkToFile:=False, SaveWithDocument:=True, Range:=.Range.Characters.Last)
    'Resize the image
    With wdIshp
      .LockAspectRatio = True
      .Height = InchesToPoints(1.5)
    End With
  End With
End With
End Sub

【讨论】：

完美！太感谢了。我在这上面花了很多时间，只是无法完全正确地使用语法。