从类访问时间线对象，提供空对象引用？

Question

所有迟到的人，这个问题仍然有效，尚未得到答案，您可能会在下面看到一个不相关的语法错误，一位好成员为我找到了

错误：

TypeError: Error #1009: Cannot access a property or method of a null object reference.
    at Player()
    at Maintest_fla::MainTimeline/createPlayer()

当我尝试添加实例名称为 world 的对象中的实例名称 wall0x 对象时，我发现我收到了一个空对象错误。 也忽略一长串不相关的变量。

package 
{

    import flash.display.MovieClip;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.events.TimerEvent;
    import flash.filters.BlurFilter;
    import flash.utils.Timer;



    public class Player extends MovieClip
    {
        // player settings



        private var _rotateSpeedMax:Number = 20;
        public var _gravity:Number = .10;
        // projectile gun settings
        public var _bulletSpeed:Number = 4;
        public var _maxDistance:Number = 200;
        public var _reloadSpeed:Number = 250;//milliseconds
        public var _barrelLength:Number = 20;
        public var _bulletSpread:Number = 5;
        // gun stuff
        private var _isLoaded:Boolean = true;
        private var _isFiring:Boolean = false;
        private var _endX:Number;
        private var _endY:Number;
        private var _startX:Number;
        private var _startY:Number;
        private var _reloadTimer:Timer;
        private var _bullets:Array = [];

        // array that holds walls

        public var _solidObjects:Array = [];

        //
        private var _player:MovieClip;
        private var _dx:Number;
        private var _dy:Number;
        private var _pcos:Number;
        private var _psin:Number;
        public var _trueRotation:Number;



        public function Player()
        {

            // constructor code   //Right hereVVVthe instance name is wall0x and it's in the object world on the stage.                            
                _solidObjects = [MovieClip(root).world.wall01,MovieClip(root).world.wall02,MovieClip(root).world.wall03,MovieClip(root).world.wall04];


            /*addEventListener(Event.ENTER_FRAME, enterFrameHandler);
            addEventListener(MouseEvent.MOUSE_DOWN, onMouseDownHandler);
            addEventListener(MouseEvent.MOUSE_UP, onMouseUpHandler);*/
           }

        }
}

我在第 2 帧中使用的代码创建播放器，然后不断将其和弦设置为另一个对象。

stage.addEventListener(Event.ENTER_FRAME, createPlayer);
function createPlayer(e:Event):void
        {


            // attach player movieclip from library

            // position player in center
            if (character!=null&&_player!=null)
            {

                _player.x = character.x + 5;
                _player.y = character.y + 5;
            }
            else if (_player ==null && world.wall01 != null)
            {
            var _player:Player;


                _player = new Player();

                // add to display list
                stage.addChild(_player);
            }
        }

Answer 1

首先：这两行有语法错误：

_player.x = MovieClip.(root).character.x + 5;
_player.y = MovieClip.(root).character.y + 5;

MovieClip 后面不应该有句号，所以应该是这样的：

_player.x = MovieClip(root).character.x + 5;
_player.y = MovieClip(root).character.y + 5;

第二：你总是在每一帧创建一个新的播放器。在您的 createPlayer 方法中，您有以下条件：

if(character != null && _player != null)  //_player is not a defined in this scope, so it will either throw an error, or always return null/undefined

您没有在该框架的范围或createPlayer 方法的范围内定义_player var，您已在else 语句的范围内定义它（这仅在else 中可用声明）

将var _player:Player 与其他帧范围变量一起移动到时间线代码的顶部。

第三：您试图在Player 构造函数中访问root，问题在于，当构造函数运行时，您的Player 尚未出现在显示树上，因此在您将播放器添加到舞台之前，root 为空。

示例：

_player = new Player(); //this will run your contructor, but root will be null
stage.addChild(_player); //after this, your Player class will now have access to root/stage/parent object

更改您的Player 类，使其在尝试访问root 之前侦听ADDED_TO_STAGE。

    public function Player()
    {
        this.addEventListener(Event.ADDED_TO_STAGE, init);
        // constructor code

    }

    private function init(e:Event):void {
        this.removeEventListener(Event.ADDED_TO_STAGE, init);
        _solidObjects = [MovieClip(root).world.wall01,MovieClip(root).world.wall02,MovieClip(root).world.wall03,MovieClip(root).world.wall04];
        addEventListener(Event.ENTER_FRAME, enterFrameHandler);
        addEventListener(MouseEvent.MOUSE_DOWN, onMouseDownHandler);
        addEventListener(MouseEvent.MOUSE_UP, onMouseUpHandler);
    }