了解 Delphi & C++ Builder 中的 TBitmap.Scanline

Question

Delphi & C++ Builder 有一个带有 Scanline 属性的 TBitmap 类，它返回位图像素的内存。当我查看 BMP 文件的十六进制编辑器时，这似乎有所不同。

我正在尝试将 C++ Builder 应用程序移植到 Java，并希望了解 Scanline 中的算法。如果我有文件，如何像 Scanline 那样生成内存阵列？ Scanline 背后的具体规格是什么？

澄清：BMP 是 Windows 24 位 DIB。我没有在代码中提供任何其他信息； C++ Builder 似乎将它加载到某种类型的内存结构中，但它不是逐字节的。想知道那个结构的规格是什么。

Answer 1

位图文件以BITMAPFILEHEADER开头，bfOffBits成员指定图像数据的起始地址。这是 Dh 处的 DWORD（第 11-14 个字节）。 Delphi VCL 的结构在'windows.pas'中定义为TBitmapFileHeader。

ScanLine 的最后一行指向此图像数据（自下而上）。 VCL 在dsBm(a BITMAP) 成员的bmBits 成员或图像的DIBSECTION 中具有此值。当请求扫描线时，VCL 根据请求的行、行中的像素数（图像的宽度）和组成像素的位数计算偏移量，并返回一个指向地址的指针，并将该偏移量添加到bmBits。真的是逐字节的图像数据。

以下 Delphi 示例代码将 24 位位图读取到文件流中，并将每个读取的像素与 Bitmap.ScanLine 对应的像素数据进行比较：

procedure TForm1.Button1Click(Sender: TObject);
var
  BmpFile: string;
  Bmp: TBitmap;

  fs: TFileStream;
  FileHeader: TBitmapFileHeader;
  InfoHeader: TBitmapInfoHeader;
  iHeight, iWidth, Padding: Longint;

  ScanLine: Pointer;
  RGBFile, RGBBitmap: TRGBTriple;
begin
  BmpFile := ExtractFilePath(Application.ExeName) + 'Attention_128_24.bmp';

  // laod bitmap to TBitmap
  Bmp := TBitmap.Create;
  Bmp.LoadFromFile(BmpFile);
  Assert(Bmp.PixelFormat = pf24bit);

  // read bitmap file with stream
  fs := TFileStream.Create(BmpFile, fmOpenRead or fmShareDenyWrite);
  // need to get the start of pixel array
  fs.Read(FileHeader, SizeOf(FileHeader));
  // need to get width and height of bitmap
  fs.Read(InfoHeader, SizeOf(InfoHeader));
  // just a general demo - no top-down image allowed
  Assert(InfoHeader.biHeight > 0);
  // size of each row is a multiple of the size of a DWORD
  Padding := SizeOf(DWORD) -
      (InfoHeader.biWidth * 3) mod SizeOf(DWORD); // pf24bit -> 3 bytes

  // start of pixel array
  fs.Seek(FileHeader.bfOffBits, soFromBeginning);


  // compare reading from file stream with the value from scanline
  for iHeight := InfoHeader.biHeight - 1 downto 0  do begin

    // get the scanline, bottom first
    ScanLine := Bmp.ScanLine[iHeight];

    for iWidth := 0 to InfoHeader.biWidth - 1 do begin

      // read RGB from file stream
      fs.Read(RGBFile, SizeOf(RGBFile));

      // read RGB from scan line
      RGBBitmap := TRGBTriple(Pointer(
                      Longint(ScanLine) + (iWidth * SizeOf(TRGBTriple)))^);

      // assert the two values are the same
      Assert((RGBBitmap.rgbtBlue = RGBFile.rgbtBlue) and
             (RGBBitmap.rgbtGreen = RGBFile.rgbtGreen) and
             (RGBBitmap.rgbtRed = RGBFile.rgbtRed));
    end;
    // skip row padding
    fs.Seek(Padding, soCurrent);
  end;
end;

关于在十六进制编辑器中查找位图文件的像素数据开始的图片：