【问题标题】:Remote ssh connection from within Emacs来自 Emacs 的远程 ssh 连接
【发布时间】:2012-05-16 17:58:31
【问题描述】:

包括this 在内的几个问题讨论了Emacs 中与ssh 连接相关的各个方面。不过,我还没有找到问题的答案:如何从 Emacs 中通过 ssh 连接到远程机器?

我不想在 Emacs 中编辑远程机器上的文件。我知道M-x shell 在我的本地机器上打开一个shell,我知道使用TRAMP 在远程机器上通过ssh 编辑文件。但是,这些都与这个问题无关。

(与其投票结束,不如将问题迁移到另一个站点。)

编辑:相关讨论here。

【问题讨论】:

  • M-x shell 和 Tramp do 都与您所述的问题有关。所以请具体解释他们不做什么。我知道你想做的不仅仅是 Tramp 让你做的事情,但你想做哪些 M-x shell 不允许你做的事情?
  • 我想输入M-x ssh 或类似的东西来创建一个ssh 连接,就像我可以输入M-x sql-postgresql 来直接创建一个到数据库的连接。 M-x shell 只是打开一个外壳,我可以从中 ssh 或其他任何东西。我在问是否有办法从 Emacs 中直接进行 ssh。
  • 您实际上想对不编辑远程文件或打开远程终端的 ssh 做什么?
  • 我想打开一个远程终端——我想直接从 Emacs SSH 到远程机器,而不使用外部 shell。如果这不可能,那很好——这就是问题的答案。
  • 这是否意味着问题的整个 ssh 焦点是一个红鲱鱼,而您想要的只是 Emacs 中的本机外壳(eshell 已经提到)?听起来您在该 shell 中运行 ssh 以连接到远程机器的事实在很大程度上无关紧要?

标签: emacs ssh


【解决方案1】:

也许ssh.el 是您正在寻找的。 ssh 命令提供了一种通过 ssh 在 Emacs 中创建远程 shell 的单步方式,包括以自然方式指定用户名,并在需要时启用tramp 目录跟踪。

【讨论】:

    【解决方案2】:

    首先,我不知道有一个原生 elisp ssh 客户端(并且不认为编写一个有很大的动机),所以您肯定需要与外部 ssh 客户端进程进行交互。

    由于您希望以交互方式使用 ssh,ssh 进程需要连接本地端的终端。

    因此问题就变成了:Emacs 是否实现了一个可以附加 ssh 进程的终端?

    答案是:是的——term.el 提供了一个健壮的终端实现,通过它可以直接运行 ssh,而不需要 shell。

    如果你运行 M-x term RET 你会被提示输入一个程序。 (它默认为 shell,但这肯定不是您可以运行的唯一进程类型。)

    由于未知原因,交互式term(和ansi-term)函数不支持将参数传递给指定的程序,如果您希望运行类似ssh user@host 的程序,它们的用处就会降低。您可以改为指定一个处理参数的脚本,但我们也可以在 elisp 中进行管理:

    term 函数实际上是一个简单的包装器,它调用make-term 来启动程序,然后设置适当的模式。由于make-term确实接受程序参数,因此复制和修改term 的定义以适合您自己的目的非常简单。

    这是一个非常简单的实现:

    (defun my-ssh (user host port)
      "Connect to a remote host by SSH."
      (interactive "sUser: \nsHost: \nsPort (default 22): ")
      (let* ((port (if (equal port "") "22" port))
             (switches (list host "-l" user "-p" port)))
        (set-buffer (apply 'make-term "ssh" "ssh" nil switches))
        (term-mode)
        (term-char-mode)
        (switch-to-buffer "*ssh*")))
    

    或许这样更可取:

    (defun my-ssh (args)
      "Connect to a remote host by SSH."
      (interactive "sssh ")
      (let ((switches (split-string-and-unquote args)))
        (set-buffer (apply 'make-term "ssh" "ssh" nil switches))
        (term-mode)
        (term-char-mode)
        (switch-to-buffer "*ssh*")))
    

    显然还有改进的余地,但我认为这是相当有用的。

    您应该确保您熟悉term-mode 的怪癖。见:

    • M-: (info "(emacs) Terminal emulator") RET
    • M-: (info "(emacs) Terminal Mode") RET
    • C-hf term-mode RET

    【讨论】:

    • 如何指定端口?我对您的示例进行了一些修改,但找不到指定“-p PORT”的位置。我没有信息页面,所以我必须在其他地方搜索。
    • 我添加了一个端口参数。你是如何安装 Emacs 的?没有可用的信息手册是一个重大缺陷。
    • 旁注:在 Debian 中,信息页面在包 emacs23-common-non-dfsg 中的不同许可下可用。
    • n.b.有关此代码的略微改进版本(添加特定历史记录,以及更好的缓冲区命名),请参阅stackoverflow.com/a/19837365/324105
    【解决方案3】:

    事实证明,有你想要的:

    (setq rlogin-program "ssh")
    (setq rlogin-process-connection-type t)
    

    然后M-x rlogin RET <myhost> RET 会这样做。

    【讨论】:

    • 如何指定用户名、密码和端口? M-x rlogin RET <host> <username> RET 和 M-x rlogin RET <username@host:port> RET 都不起作用。 emacswiki.org/emacs/RloginMode 没用。
    • 那些不起作用,因为 ssh host username 和 ssh username@host:port 都不是有效的调用。您可以使用username@host -p port 或host -l username -p port。或使用(setq rlogin-explicit-args '("-l" "username" "-p" "port"))。当然,您通常根本不需要指定端口。检查C-h f rlogin。由于rlogin 使用comint-mode,您可能还希望ansi-color-for-comint-mode-on 也可能有用。
    • 我发现term 与term-char-mode 的方法比这更可靠。特别是,远程 shell 中的 TAB 完成工作。对于 shell,comint 似乎更适合本地而不是远程,而term 没有做出任何此类假设。
    • 带有rlogin-mode-map 的 Emacs 24 错误已在 HEAD(或从 24.0.97 开始)中修复,任何人都想知道这一点。如果您想直接修补它,这是所需的差异:bzr.savannah.gnu.org/lh/emacs/emacs-24/revision/107988/lisp/net/…
    • @phils:谢谢,我看到需要的格式实际上是因为细节应该直接传递给ssh。这有效,我能够登录到机器。 ANSI 转义序列显示不正确,但我也会参考您的答案。
    【解决方案4】:

    我不确定我是否理解。打开M-x ansi-term 并在那里运行ssh user@host?

    【讨论】:

    • 那么 Emacs 本身没有我们应该使用的 shell 程序吗?解决方案是简单地制作一个 shell(即使使用“M-x shell”),然后从那里 ssh 进入?我将它与 Emacs 自身进行远程连接的 Emacs SQL 模式进行比较。
    • 有一个用 Elisp 编写的 shell,叫做 eshell,如果你是这个意思的话。
    • 正确,有很多shell实现,但是AFAIK没有ssh客户端实现。
    • @SabreWolfy 不,Emacs 有一个名为 TRAMP 的 ssh/ftp 包装器,它负责连接远程系统,因此您可以像往常一样使用C-x C-f 打开远程文件
    • @kindahero:是的,但我想通过 ssh 连接,而不是打开远程文件。
    猜你喜欢
    • 1970-01-01
    • 2020-10-31
    • 2020-09-25
    • 1970-01-01
    • 1970-01-01
    • 2020-06-15
    • 2019-03-11
    • 2016-11-19
    • 2021-01-25
    相关资源
    最近更新 更多