VB.NET WithEvents 关键字行为 - VB.NET 编译器限制？

Question

我正在努力让 C# 变得像我对 VB.NET（我的工作场所使用的语言）一样熟悉。学习过程中最好的事情之一是，通过学习另一种语言，您往往会更多地了解您的主要语言——像这样弹出的小问题：

根据我找到的来源和过去的经验，VB.NET 中声明为 WithEvents 的字段能够引发事件。我知道 C# 没有直接的等价物——但我的问题是：VB.NET 中的字段 without 这个关键字不能引发事件，有没有办法在 C# 中创建同样的行为？ VB 编译器是否只是阻止这些对象处理它们的事件（同时实际上允许它们像往常一样引发事件）？

我只是好奇；我对这个问题没有任何特别的申请...

Answer 1

省略 WithEvents 不会阻止成员引发事件。它只是阻止您在他们的事件中使用“句柄”关键字。

这是 WithEvents 的典型用法：

Class C1
    Public WithEvents ev As New EventThrower()
    Public Sub catcher() Handles ev.event
        Debug.print("Event")
    End Sub
End Class

这是一个不使用 WithEvents 并且大致等效的类。它说明了为什么 WithEvents 非常有用：

Class C2
    Private _ev As EventThrower
    Public Property ev() As EventThrower

        Get
            Return _ev
        End Get

        Set(ByVal value As EventThrower)
            If _ev IsNot Nothing Then
                    removehandler _ev.event, addressof catcher
            End If
            _ev = value
            If _ev IsNot Nothing Then
                    addhandler _ev.event, addressof catcher
            End If
        End Set
    End Property

    Public Sub New()
        ev = New EventThrower()
    End Sub

    Public Sub catcher()
        Debug.print("Event")
    End Sub
End Class