如何将函数映射到使用 Haskell 中的 Monad 类的多个构造函数参数上？

Question

我偶然发现的问题与 >>= 应用程序对这样的示例类型有关：

data ThreeArgs a = ThreeArgs a a a deriving (Show,Eq)

instance Functor ThreeArgs where
    fmap f (ThreeArgs a b c) = ThreeArgs (f a) (f b) (f c)

instance Applicative ThreeArgs where
    pure x = ThreeArgs x x x
    (ThreeArgs a b c) <*> (ThreeArgs p s q) = ThreeArgs (a p) (b s) (c q)

我会声明一个 Monad 实例如下：

instance Monad ThreeArgs where
    return x = ThreeArgs x x x
    (ThreeArgs a b c) >>= f = f ... -- a code I need to complete

是的，看起来f 似乎应用于所有三个ThreeArgs 构造函数参数。如果我完成最后一行

(ThreeArgs a b c) >>= f = f a

那么编译器没有任何抱怨，而结果是：

*module1> let x = do { x <- ThreeArgs 1 2 3; y <- ThreeArgs 4 6 7; return $ x + y }
*module1> x
ThreeArgs 5 5 5 

这意味着求和会导致具有相同参数值的上下文，尽管正确的输出应该是ThreeArgs 5 8 10。一旦我编辑到

(ThreeArgs a b c) >>= f = (f a) (f b) (f c)

编译器警报：

 Couldn't match expected type `ThreeArgs b
                                -> ThreeArgs b -> ThreeArgs b -> ThreeArgs b'
              with actual type `ThreeArgs b'

所以，我看到一个严重的错误指导了我的理解，但我仍然很难理解 Haskell 中的单子类和其他类似的东西。大概，我想在这里使用递归还是其他什么？

Answer 1

ThreeArgs 与((->) Ordering) 同构。证人：

to :: ThreeArgs a -> Ordering -> a
to (ThreeArgs x _ _) LT = x
to (ThreeArgs _ y _) EQ = y
to (ThreeArgs _ _ z) GT = z

from :: (Ordering -> a) -> ThreeArgs a
from f = ThreeArgs (f LT) (f EQ) (f GT)

您的Functor 和Applicative 实例与((->) r) 的工作方式相匹配，因此我们只需使其与its Monad one 的工作方式相匹配，我们就完成了。

instance Monad ThreeArgs where
    ThreeArgs x y z >>= f = ThreeArgs x' y' z' where
        ThreeArgs x' _ _ = f x
        ThreeArgs _ y' _ = f y
        ThreeArgs _ _ z' = f z

顺便说一下，像ThreeArgs 这样的数据结构的通用术语是“可表示函子”，如果您想了解更多相关信息。