Prolog检查列表是否包含偶数个元素

Question

我必须检查一个列表是否包含偶数个没有内置的元素。

例子：

containsEvenNumber([a,b,c,a,a], a).

返回假

containsEvenNumber([a,b,c,a], a).

返回真

当前状态：

not(A) :-
    A, !,
    fail.
not(_).
equal([E|_], E).
containsEvenNumber([], _).
containsEvenNumber([E|Tail], E) :-
    unevenCount(Tail, E).

containsEvenNumber([Head|Tail], E) :-
    not(equal([Head|Tail], E)),
    evenCount(Tail, E).

evenCount([], _).
evenCount([E|Tail], E) :-
    unevenCount(Tail, E).

evenCount([Head, Tail], E) :-
    not(equal([Head|Tail], E)),
    unevenCount(Tail, E).

unevenCount([], _) :-
    fail.
unevenCount([E, Tail], E) :-
    evenCount(Tail, E).

unevenCount([Head, Tail], E) :-
    not(equal([Head|Tail], E)),
    unevenCount(Tail, E).

我尝试在元素出现时在状态之间切换。 它不起作用，因为我从不进入头部不是元素的状态，或者更确切地说，我也进入状态并在头部是元素时返回 false。

我怎样才能让它工作/修复它？

Answer 1

“状态之间的切换”其实是解决这个问题的好办法。逻辑应该遵循这些简单的规则：

1. 如果Xs 中有奇数个X 元素，则[X|Xs] 中有偶数个X 元素。

2. 如果X和Y不同，则[Y|Xs]中有偶数个X元素，Xs中有偶数个X元素。

3. 如果Xs 中有偶数个X 元素，则[X|Xs] 中有奇数个X 元素。

4. 如果X 和Y 不同，则[Y|Xs] 中有奇数个X 元素，而Xs 中有奇数个X 元素。

那么你就有了基本情况：

[] 中有偶数个任意元素。

[X] 中有奇数个X。

您只需将这些规则编写为 Prolog。但是，您的实现存在一些问题。

在少数情况下，您将列表写为[Head, Tail] 而不是[Head|Tail]。 [Head, Tail] 是正好包含两个元素的列表。此外，unevenCount/2 的基本情况（我假设您的意思是奇数）不正确。如果您有一个始终失败的基本案例，那么您的谓词将始终失败。除了少数例外，您应该编写谓词从句以成功，而不是失败。无法成功时会自动失败。

让我们试着写出上面的规则。 ISO Prologs 已经有\+，所以你不需要定义not/1。另外，写equal([E|_], E). 是不必要的。您可以直接在代码中简单地执行此操作。

evenCount(_, []).          % base case for even
evenCount(X, [X|Xs]) :-    % rule #1
    oddCount(X, Xs).
evenCount(X, [Y|Xs]) :-    % rule #2
    dif(X, Y),
    evenCount(X, Xs).

oddCount(X, [X]).          % base case for odd
oddCount(X, [X|Xs]) :-     % rule #3
    evenCount(X, Xs).
oddCount(X, [Y|Xs]) :-     % rule #4
    dif(X, Y),
    oddCount(X, Xs).

SWI Prolog 定义了dif/2。您也可以使用\==，但它不是像dif/2 那样纯粹定义（因此行为不一样）。