动作脚本函数可以找出自己的名称吗？

Question

鉴于以下情况

function A(b:Function)   { }

如果是函数A()，我们可以确定作为参数'b'传入的函数的名称吗？ AS2 和 AS3 的答案是否不同？

Answer 1

我使用以下：

private function getFunctionName(e:Error):String {
    var stackTrace:String = e.getStackTrace();     // entire stack trace
    var startIndex:int = stackTrace.indexOf("at ");// start of first line
    var endIndex:int = stackTrace.indexOf("()");   // end of function name
    return stackTrace.substring(startIndex + 3, endIndex);
}

用法：

private function on_applicationComplete(event:FlexEvent):void {
    trace(getFunctionName(new Error());
}

输出： FlexAppName/on_applicationComplete()

有关该技术的更多信息，请访问 Alex 的网站：

http://blogs.adobe.com/aharui/2007/10/debugging_tricks.html

Answer 2

我一直在尝试建议的解决方案，但在某些时候我都遇到了麻烦。主要是因为对固定 或 动态成员的限制。我做了一些工作并将这两种方法结合起来。请注意，它仅适用于公开可见的成员 - 在所有其他情况下返回 null。

    /**
     * Returns the name of a function. The function must be <b>publicly</b> visible,
     * otherwise nothing will be found and <code>null</code> returned.</br>Namespaces like
     * <code>internal</code>, <code>protected</code>, <code>private</code>, etc. cannot
     * be accessed by this method.
     * 
     * @param f The function you want to get the name of.
     * 
     * @return  The name of the function or <code>null</code> if no match was found.</br>
     *          In that case it is likely that the function is declared 
     *          in the <code>private</code> namespace.
     **/
    public static function getFunctionName(f:Function):String
    {
        // get the object that contains the function (this of f)
        var t:Object = getSavedThis(f); 

        // get all methods contained
        var methods:XMLList = describeType(t)..method.@name;

        for each (var m:String in methods)
        {
            // return the method name if the thisObject of f (t) 
            // has a property by that name 
            // that is not null (null = doesn't exist) and 
            // is strictly equal to the function we search the name of
            if (t.hasOwnProperty(m) && t[m] != null && t[m] === f) return m;            
        }
        // if we arrive here, we haven't found anything... 
        // maybe the function is declared in the private namespace?
        return null;                                        
    }

Answer 3

这是一个简单的实现

    public function testFunction():void {
        trace("this function name is " + FunctionUtils.getName()); //will output testFunction
    }

在一个名为 FunctionUtils 的文件中，我把这个...

    /** Gets the name of the function which is calling */
    public static function getName():String {
        var error:Error = new Error();
        var stackTrace:String = error.getStackTrace();     // entire stack trace
        var startIndex:int = stackTrace.indexOf("at ", stackTrace.indexOf("at ") + 1); //start of second line
        var endIndex:int = stackTrace.indexOf("()", startIndex);   // end of function name

        var lastLine:String = stackTrace.substring(startIndex + 3, endIndex);
        var functionSeperatorIndex:int = lastLine.indexOf('/');

        var functionName:String = lastLine.substring(functionSeperatorIndex + 1, lastLine.length);

        return functionName;
    }

Answer 4

名字？不，你不能。但是，您可以做的是测试参考。像这样的：

function foo()
{
}

function bar()
{
}

function a(b : Function)
{
   if( b == foo )
   {
       // b is the foo function.
   }
   else
   if( b == bar )
   {
       // b is the bar function.
   }
}

Answer 5

我不知道它是否有帮助，但可以获得对 arguments 函数调用者的引用（据我所知，仅在 ActionScript 3 中）。

Answer 6

通常将 arguments.callee 与 toString() 和 match 一起使用：

function foo(){return arguments.callee.toString().match(/\s\w+/).toString()}

参考文献

• arguments callee method

• Tracing Function Arguments

Answer 7

您是否只是在寻找参考，以便之后可以再次调用该函数？如果是这样，请尝试将函数设置为变量作为参考。 var lastFunction:函数;

var func:Function = function test():void
{
    trace('func has ran');
}

function A(pFunc):void
{
    pFunc();
    lastFunction = pFunc;
}
A(func);

现在如果你需要引用上次运行的函数，你可以通过调用 lastFunction 来实现。

我不确定您到底想做什么，但也许这会有所帮助。