Guile 方案中如何使用惰性求值？

Question

我写了一段代码，它使用惰性求值来产生无限的数据结构，但是有一个错误。

代码如下：

#!/usr/bin/guile \
-e main -s
!#
(define ints-f 
    (lambda (n) 
        (let ((n1 (delay (ints-f (+ n 1)))))
        (cons n (force n1)))))
(define (main args)
    (display (car (ints-f 3) ))
    (newline)
    )

这给出了一个错误，说堆栈溢出。这意味着即使没有调用强制也正在执行。如何解决这个问题？

#!/usr/bin/guile \
-e main -s
!#
(define ints-f 
    (lambda (n) 
        (let ((n1 (delay (ints-f (+ n 1)))))
        (cons n n1))))
(define (main args)
    (display (car (ints-f 3) ))
    (newline)
    )

上面的代码给出了 3 的预期输出，但是如果我在下面的代码中使用 cdr

#!/usr/bin/guile \
-e main -s
!#
(define ints-f 
    (lambda (n) 
        (let ((n1 (delay (ints-f (+ n 1)))))
        (cons n n1))))
(define (main args)
    (display (cdr (ints-f 3) ))
    (newline)
    )

它打印一个承诺对象。

如何在 guile 方案中使用惰性求值？

Answer 1

您是否正在尝试创建流？您可能希望咨询(srfi srfi-41) 模块以了解其实现。 （披露：我编写了模块代码的 Guile 特定部分；其他所有内容都从 the reference implementation 移植。）

(use-modules (srfi srfi-41))
(define-stream (ints-f n)
  (stream-cons n (ints-f (1+ n))))

请注意，define-stream 和 stream-cons 是在幕后协同工作以构建（SRFI 45 风格）delay/force 的宏。^†

使用示例：

> (stream->list 10 (ints-f 100))
(100 101 102 103 104 105 106 107 108 109)

---

^† 特别是，您的函数扩展为：

(define (ints-f n)
  (lazy (eager (cons (delay n)
                     (lazy (ints-f (1+ n)))))))

您可以使用：

> (define x (ints-f 100))
> (force (car (force x)))
100
> (force (car (force (cdr (force x)))))
101

Answer 2

第一个 sn-p 不正确，您在构建序列时强制使用该值，因此违背了惰性求值的整个目的。另一方面，第二个 sn-p 看起来是对的——尽管它可以简化一点：

(define (ints-f n)
  (cons n (delay (ints-f (+ n 1)))))

调用cdr 时得到一个promise 是正常，它是一个用delay 构建的thunk，只有在forced 时才会产生它的值。事实上，如果你想窥探无限序列的元素，你必须使用一个过程来遍历你感兴趣的部分：

(define (take seq n)
  (if (= n 0)
      '()
      (cons (car seq)
            (take (force (cdr seq)) (- n 1)))))

同样：

(define (get seq idx)
  (if (= idx 0)
      (car seq)
      (get (force (cdr seq)) (- idx 1))))

例如：

(take (ints-f 5) 5)
=> '(5 6 7 8 9)

(get (ints-f 5) 5)
=> 10