【问题标题】:Implement higher-order effect interpreter实现高阶效果解释器
【发布时间】:2021-12-13 04:24:47
【问题描述】:

我正在尝试实现高阶效果的解释器。

我有一个基础效果:

{-# LANGUAGE TemplateHaskell #-}
{-# OPTIONS_GHC -fplugin=Polysemy.Plugin #-}

module Hetchr.Commons.Cat where

import Polysemy
import Polysemy.Internal.Tactics

data In = In

newtype Out = Out Int
  deriving stock (Show)
  deriving newtype (Num)

data TargetE (m :: Type -> Type) (a :: Type) where
  ActA :: In -> TargetE m Out

makeSem ''TargetE

runTargetE :: InterpreterFor TargetE e
runTargetE = interpret $ \case
  ActA _ -> return $ Out 1

还有一个高阶效应:

data ProxyE (m :: Type -> Type) (a :: Type) where
  ProxyA :: (In -> m Out) -> ProxyE m Out
  FunPA :: In -> ProxyE m Out

makeSem ''ProxyE

打算用作:

main :: IO ()
main = print =<< runM (runTargetE $ runProxyE $ proxyA funPA)

我有一个执行助手:

proxyAImpl :: Member TargetE r => (In -> Sem r Out) -> Sem r Out
proxyAImpl f = (+) <$> f In <*> actA In

但是,我很难实现:

runProxyE :: Member TargetE r => InterpreterFor ProxyE r
runProxyE = interpretH $ \case
  ProxyA f -> do
    f' <- bindT f
    ??? proxyAImpl f'
  FunPA x -> liftT $ actA x

我没有找到很多例子,我对类型感到困惑,有什么提示吗?

【问题讨论】:

    标签: haskell haskell-polysemy


    【解决方案1】:

    实际上,如果我理解正确的话,你不能创建那种没有多态类型的实现的解释器,所以我必须调整我的代码:

    proxyAImpl :: (Functor f, Member TargetE r) => (In -> Sem r (f Out)) -> Sem r (f Out)
    proxyAImpl f = do
      left <- f In
      right <- actA In
      return $ fmap (+ right) left
    
    runProxyE :: Member TargetE r => InterpreterFor ProxyE r
    runProxyE = interpretH $ \case
      ProxyA f -> proxyAImpl (runTSimple . f)
      FunPA x -> liftT $ actA x
    

    【讨论】:

      猜你喜欢
      • 1970-01-01
      • 1970-01-01
      • 2021-08-03
      • 1970-01-01
      • 1970-01-01
      • 1970-01-01
      • 1970-01-01
      • 1970-01-01
      • 1970-01-01
      相关资源
      最近更新 更多