继续单子向前跳跃

Question

可以在带有延续单子的程序中向后跳转：

{-# LANGUAGE RecursiveDo #-}

import Control.Monad.Fix
import Control.Monad.Trans.Cont

setjmp = callCC (\c -> return (fix c))

backward = do
  l <- setjmp
  -- some code to be repeated forever
  l

但是当我尝试向前跳转时，GHC 不接受：

forward = mdo
  l
  -- some dead code
  l <- setjmp  
  return ()

这不起作用，因为在Control.Monad.Trans.Cont 中定义的延续单子转换器ContT 没有MonadFix (ContT r m) 的实例。有关详细信息，请参阅Levent Erkok's thesis 的第 5.1 节。

有没有一种方法可以在没有值递归的情况下对延续单子进行前向跳转编码？

ContT 的替代定义是否有 MonadFix (ContT r m) 的实例？ Magnus Carlsson 有一个 unpublished draft 提出了这样的建议，但我不知道在我的情况下该怎么做。

Answer 1

如果您将死代码移动到callCC 中，您可以这样做，如下所示：

import Control.Monad.Cont

forward :: ContT () IO ()
forward = do
  callCC $ \skip -> do
    skip ()
    lift $ putStrLn "This is not executed"
  lift $ putStrLn "Control flow continues here"

main :: IO ()
main = runContT forward return

不可能完全按照您的意愿行事。要了解原因，请考虑以下示例：

mdo
  l
  c <- lift getChar
  l <- if c == 'a' then setjmp else return (return ())
  lift $ putStrLn "end"

这应该怎么做？

---

您也可以稍后跳回被跳过的代码。您只需将延续传递给您跳过的代码。使用您的示例，goto L2: L1: some code; goto END; L2: goto L1; END: return 可以实现为：

import Control.Monad.Cont

forward :: ContT () IO ()
forward = do
  callCC $ \end -> do
    l1 <- callCC $ \l2 -> do
      callCC $ \l1 -> l2 l1
      liftIO $ putStrLn "In L1"
      end ()
    liftIO $ putStrLn "In L2"
    l1 ()
  liftIO $ putStrLn "End"

main :: IO ()
main = runContT forward return

在这里，我们将延续到我们跳过的部分 (l1) 传递回外部代码，以便它可以跳转到那里。