匿名方法对 TypeInfo 的奇怪行为

Question

对于需要泛型类型“族”的一段代码，我尝试使用TypeInfo 来检索所需信息。

class function GetTypeKind<T>:TTypeKind;

对于大多数类型，我可以弄清楚这一点。但是匿名方法类型的行为出乎意料。

我有一个匿名方法类型定义为：

TMethodProc = reference to procedure;

我尝试获取类型信息：

MyKind := GetTypeKind<TMethodProc>;

class function GetTypeKind<T>:TTypeKind;
var 
  TI: PTypeInfo;
begin
  TI := TypeInfo(T);

  ...
end;

我知道匿名方法背后有一些编译器的魔力。但我得到以下结果：

TI.TypeData.IntfParent == IInterface
TI.TypeData.IntfFlags == [(out of bounds)6]

标志有一个意外的值，TIntfFlag 有三个值，所以 6 是意外的。 GUID 也不是 guid。它有一组相同的 8 个字节的重复集，大部分为 00。例如 (0, 225, 48, 180, 0, 0, 0, 0, 0, 225, 48, 180, 0, 0, 0, 0)

匿名方法是否从TypeInfo 中排除，或者通过一些调整是否有用。

另外，（奇怪的）6 是一个未记录的功能，还是可以有任何价值？

Answer 1

这并没有什么不寻常的地方。

匿名方法被实现为编译器生成的接口，该接口具有与匿名方法相同签名的Invoke() 方法。这就是为什么TTypeKind 是tkInterface 而IntfParent 是IInterface。

接口后面是编译器生成的实现类，其中包含捕获的变量，以及Invoke() 实现中的匿名方法主体。

How are anonymous methods implemented under the hood?

IntfFlags 是 TIntfFlagsBase，它是 Set 的 TIntfFlag 枚举值：

TIntfFlag = (ifHasGuid, ifDispInterface, ifDispatch);

ifHasGuid
接口有一个 GUID（全局唯一标识符）。

ifDisp接口
是一个调度接口。

如果调度
可以发货。

Set 是值的位掩码。每个枚举值都由掩码中的特定位表示。在TIntfFlagsBase 内，ifHasGuid 是位 0，ifDispInterface 是位 1，ifDispatch 是位 2。因此，数值 6 (110b) 将是 ifDispInterface 和 ifDispatch 标志启用，但不是 ifHasGuid 标志。因此，IntfGuid 没有有意义的值，但仍会占用TTypeData 中的空间以用于对齐目的。

---

更新：我使用 XE2 进行了测试，果然，我看到 IntfFlags 设置为序数 64（如您所见，TIntfFlag(6)）而不是预期的序数 6。我看到的和你看到的唯一区别是我看到Guid 完全是空的（全为零）。

---

更新：显然，对于启用了方法信息的接口（@98​​7654352@ 指令）或表示匿名方法类型的接口确实存在其他标志，这些标志在 @987654353 中未表示@枚举。我已经为此提交了错误报告：

RSP-24631: System.TypInfo.TIntfFlag enum is missing flags

在这种情况下，TIntfFlag(6) 是匿名方法的标志。

来自Undocumented "Interface flag" for IInvokable?：

似乎 TIntfFlag 枚举自 Delphi6 以来从未扩展过（我认为那是在引入接口 RTTI 时） - 我可以确认至少自从 XE 以来，带有 $M+ 的接口类型获得了第四个标志（让我们称之为ifHasMethodInfo) 设置。

如果类型是匿名方法类型...那么集合中有第 7 个枚举值。我不知道设置第 5 位和第 6 位的情况。

...

我可以用这段代码确认我的发现：

uses
  SysUtils,
  Rtti;

type
  TIntfFlagEx = (ifHasGuid, ifDispInterface, ifDispatch, ifMethodInfo, ifUnknown, ifUnknown2, ifAnonymousMethod);
  TIntfFlagsEx = set of TIntfFlagEx;

  {$M+}
  IFoo = interface
    ['{35CFB4E2-4A13-48E9-8026-C1558001F4B7}']
    procedure Main;
  end;
  {$M-}

  {$M+}
  IBar = interface(TProc)
    ['{AB2FEC1A-339F-4E58-B3DB-EC7B734F461B}']
  end;
  {$M-}

  {$M+}
  TMyProc = reference to procedure;
  {$M-}

procedure PrintIntf(typeInfo: Pointer);
var
  context: TRttiContext;
  rttiInterface: TRttiInterfaceType;
  flags: TIntfFlagsEx;
begin
  rttiInterface := context.GetType(typeInfo) as TRttiInterfaceType;
  flags := TIntfFlagsEx(rttiInterface.IntfFlags);
  Writeln(rttiInterface.Name, ' ', TValue.From(flags).ToString);
end;

begin
  PrintIntf(TypeInfo(IInterface));
  PrintIntf(TypeInfo(IInvokable));
  PrintIntf(TypeInfo(IFoo));
  PrintIntf(TypeInfo(TProc));
  PrintIntf(TypeInfo(TFunc<Integer>));
  PrintIntf(TypeInfo(TMyProc));
  PrintIntf(TypeInfo(IBar));
  Readln;
end.

打印这个：

IInterface [ifHasGuid] IInvokable [ifMethodInfo] IFoo [ifHasGuid,ifMethodInfo] TProc [ifAnonymousMethod] TFunc [ifAnonymousMethod] TMyProc [ifMethodInfo,ifAnonymousMethod] IBar [ifHasGuid,ifMethodInfo,ifAnonymousMethod]