不能用do循环在lisp中求和

Question

(defun suma (L)
  (setq var 0)
  (do 
      ((i 0 (+ i 1)))
      ((= i (length L)))
    (+ var (nth i L)))
  var)

为什么总是返回0？

它不应该返回列表 L 的总和吗？

Answer 1

+ 不修改其参数，因此，由于您从未修改 var，因此返回其初始值 0。

您需要将(+ var (nth i L)) 替换为(incf var (nth i L))，相当于(setq var (+ var (nth i L)))。

见incf。

请注意，您应该将var 与let 绑定，而不是使用setq 将其设为全局。

最重要的是，请注意您的算法在列表参数的长度上是二次的（因为nth 每次从一开始都会扫描您的列表）。

这里有一些更好的实现：

(defun sum-1 (l)
  (reduce #'+ l))

(defun sum-2 (l)
  (loop for x in l sum x))

(defun sum-3 (l)
  (let ((sum 0))
    (dolist (x l sum)
      (incf sum x))))

这是一个不好的实现：

(defun sum-4 (l)
  (apply #'+ l))

sum-4 的问题在于，如果提供的列表长度大于call-arguments-limit，它将失败。

Answer 2

我认为这是对完整学习体验的评论，但我无法在评论中添加代码。

有一种方法可以在不修改任何参数的情况下进行求和，那就是递归地进行：

(defun recsum (list)
  (if list
      (+ (first list) (recsum (rest list)))
      0))

这个版本可以通过编译器进行尾调用优化，和循环一样快：

(defun recsum2 (list &optional (accumulator 0))
  (if list
      (recsum2 (rest list) (+ accumulator (first list)))
      accumulator))

您可以使用do 来完成您想要做的事情，如下所示：

(defun suma (l)
  (do 
   ((var 0)
    (i 0 (+ i 1)))
   ((= i (length l)) var)
    (incf var (nth i l))))

但是我们通常不会在dos 的正文中做任何事情，所以它是这样的：

(defun suma (l)
  (do
   ((i 0 (+ i 1))
    (var 0 (+ var (nth i l))))
   ((= i (length l)) var)))

但是nth 和length 很慢，所以最好这样做：

(defun suma (l)
  (do* 
   ((var (first l) (+ var (first list)))
    (list (rest l) (rest list)))
   ((null list) var)))

这个在do中没有*，在空列表上返回0：

(defun suma (l)
  (do 
   ((acc 0 (+ acc (first list)))
    (list l (rest list)))
   ((null list) acc)))

但我最喜欢的是来自@sds 的reduce 版本，它也可以在空列表中返回 0，并带有 :initial-value 0

编辑：recsum2 没有返回任何内容，因此需要修复。