Lisp &rest 参数和递归调用

Question

我有以下 Common Lisp 函数：

(defun test(A &rest indexes)
  (if (null (first indexes))
      A
    (test (nth (+ 1 (first indexes)) A) (rest indexes))
  )
)

据我所知，&rest 参数在函数体中被视为列表，但由于

(rest indexes) 还返回一个列表，我一直使用嵌套列表作为参数。

例如(test '("a" "b" "c" ("d" "e")) 3 1 6 7)

在第二次调用时会导致索引为((1 6 7)) 。

有什么方法可以通过我的列表而不会出现这个问题？

Answer 1

基本样式规则：列表处理函数不要使用&rest 参数。

为什么？ Common Lisp 实现最多只能支持CALL-ARGUMENTS-LIMIT 数量的参数。此数字为 50 或更大，具体取决于实施。

这意味着您的函数可能在某些实现过程中列出不超过五十个项目。

更好：将列表作为单独的参数传递。

(defun test (A indexes)
   ...)

(test '("a" "b" "c" ("d" "e")) '(3 1 6 7))

错误的解决方案：不要使用apply，因为它不能解决参数列表有限的问题。

CLISP

[1]> call-arguments-limit
4096
[2]> (defun l1 (&rest l) l)
L1
[3]> (apply #'l1 (loop repeat 5000 collect 1))

*** - APPLY: too many arguments given to
      #<FUNCTION L1 (&REST L)
         (DECLARE (SYSTEM::IN-DEFUN L1))
         (BLOCK L1 L)>
The following restarts are available:
ABORT          :R1      Abort main loop

Answer 2

rest 是一个与first 配对的访问器函数，为您提供第一个元素和列表的其余部分。 rest 与 cdr 相同。

&rest 是一个 lambda list keyword，它会在其后面的变量名中删除剩余的参数。

你真的在寻找apply。想象一下，我创建了一个可以接受 0 个或多个数字参数并将它们相加的函数：

(defun add (&rest numbers)
  (apply #'+ numbers))

Apply 可以接受两个以上的参数。第一个是要调用的函数，除了最后一个之外，都是放在最后一个参数元素前面的额外参数。您可以保证实现支持 50 个参数，或者在特定实现支持超过 50 个的特定实现中，函数可以接受的参数数量最多。

(apply #'+ 1 2 '(3 4 5)) ; ==> 15

现在通过&rest 和apply 进行递归会导致代码效率低下，因此您应该使用高阶函数、循环宏或创建助手：

;; higher order function
(defun fetch-indexes (a &rest indexes)
  (mapcar (lambda (i) (nth i a)) indexes))

;; loop macro
(defun fetch-indexes (a &rest indexes)
  (loop :for i :in indexes
        :collect (nth i a)))

;; helper function
(defun fetch-indexes (a &rest indexes)
  (labels ((helper (indexes)
             (if (endp indexes)
                 '()
                 (cons (nth (first indexes) a)
                       (helper (rest indexes))))))
    (helper indexes)))

;; test (works the same with all)
(fetch-indexes '(a b c d) 2 3 0 1)
; ==> (c d a b)

应避免在递归中使用 apply，但我将展示它是如何完成的。

(defun fetch-indexes (a &rest indexes)
  (if (endp indexes)
      '()
      (cons (nth (first indexes) a)
            (apply #'fetch-indexes a (rest indexes)))))

在您的示例中，您有嵌套列表。为了使它起作用，您还需要将其展平。我还没有这样做，所以这些支持一个适当的元素列表。