替换嵌套引用列表中的元素会添加新元素？

Question

我有一个嵌套列表，我正在尝试非破坏性地替换它的所有元素（也在嵌套列表内）。也就是说，给定我的输入列表

'(1 '(2 3 4) '(5 6 7) 8 9)

我正在努力实现

'(0 '(0 0 0) '(0 0 0) 0 0)

我尝试了以下

 (defun subs-list (list value)
  "Replaces all elements of a list of list with given value"
  (loop for elt in list
       collect (if (listp elt)
           (subs-list elt value) 
           value)))

但是当我尝试时

(subs-list '(1 '(2 3 4) '(5 6 7) 8 9) 0)
(0 (0 (0 0 0)) (0 (0 0 0)) 0 0)

是我得到的输出。 我做错了什么？

Answer 1

我做错了什么？

您实际上已经完成了与loop 的良好合作，并且有效！请记住' 代表quote，所以：

'(1 '(2 3 4) '(5 6 7) 8 9)

等于

(quote (1 (quote (2 3 4)) (quote (5 6 7)) 8 9))
;       |  |      | | |    |      | | |   | |
       (0 (0     (0 0 0)) (0     (0 0 0)) 0 0)

你看，你的引号也被替换了（除了第一个，它在函数参数的评估过程中被消耗掉了）！一个报价就足以暂停执行。

Answer 2

Mark's answer 和wdebeaum's answer 解释为什么你会得到你得到的结果；嵌套引号意味着您实际上有一个类似(1 (quote (2 3 4)) (quote (5 6 7)) 8 9) 的列表，并且您将符号quote 替换为0，这就是您得到(0 (0 (0 0 0)) (0 (0 0 0)) 0 0) 的原因。您可能只想要 '(1 (2 3 4) (5 6 7) 8 9) 没有嵌套引号。

值得指出的是，Common Lisp 已经提供了在 cons-trees 中进行非破坏性替换的函数：subst、subst-if 和 subst-if-not。也有破坏性版本：nsubst、nsubst-if 和 nsubst-if-not。特别是，对于这种情况，您可以将所有 不是 列表的内容替换为 0，方法是使用带有 listp 和 subst-if 的 complement 函数，或者使用 listp 和 subst-if-not：

;; With `extra' elements because of the quotes:

(subst-if-not 0 #'listp '(1 '(2 3 4) '(5 6 7) 8 9))
;=> (0 (0 (0 0 0)) (0 (0 0 0)) 0 0) 

(subst-if 0 (complement #'listp) '(1 '(2 3 4) '(5 6 7) 8 9))
;=> (0 (0 (0 0 0)) (0 (0 0 0)) 0 0) 

;; With no `extra' elements:

(subst-if-not 0 #'listp '(1 (2 3 4) (5 6 7) 8 9))
;=> (0 (0 0 0) (0 0 0) 0 0)

(subst-if 0 (complement #'listp) '(1 (2 3 4) (5 6 7) 8 9))
;=> (0 (0 0 0) (0 0 0) 0 0)

如果您想采用wdebeaum's answer 中建议的混合方法而不替换引号，您可以这样做：

(subst-if 0 (lambda (x)
              (not (or (listp x)
                       (eq 'quote x))))
          '(1 '(2 3 4) '(5 6 7) 8 9))
;=> (0 '(0 0 0) '(0 0 0) 0 0)

(subst-if-not 0 (lambda (x)
                  (or (listp x)
                      (eq 'quote x)))
          '(1 '(2 3 4) '(5 6 7) 8 9))
;=> (0 '(0 0 0) '(0 0 0) 0 0)

Answer 3

您必须意识到'foo 是 (quote foo) 的语法糖，所以当您在已引用的列表中使用引号时，这样：

'(1 '(2 3 4) '(5 6 7) 8 9)

评估为：

(1 (quote (2 3 4)) (quote (5 6 7)) 8 9)

所以当你用 0 替换所有列表元素时，你会得到：

(0 (0     (0 0 0)) (0     (0 0 0)) 0 0)

您要么不需要在示例中添加额外的引号，要么需要在 subs-list 中专门处理引号运算符：

(defun subs-list (list value)
  "Replaces all elements of a list of list with given value"

  (loop for elt in list
       collect
         (cond 
           ((listp elt) 
             (subs-list elt value))
           ((eq 'quote elt)
             elt)
           (t
             value))))