Nim 中的迭代器生成函数：分配迭代器时工作，直接调用时卡住

Question

我尝试制作一个创建迭代器的过程，如下：

proc makeCDFrom(start: int): iterator(): int =
  result = iterator(): int =
    var
      i: int = start
    while i >= 0:
      echo "i:", i
      yield(i)
      dec(i)

let cdFrom6 = makeCDFrom(6)
for j in cdFrom6():
  echo "j:", j

这似乎按预期工作：

i:6
j:6
i:5
j:5
i:4
j:4
i:3
j:3
i:2
j:2
i:1
j:1
i:0
j:0

但是，最初，我尝试了这种细微的变化：

proc makeCDFrom(start: int): iterator(): int =
  result = iterator(): int =
    var
      i: int = start
    while i >= 0:
      echo "i:", i
      yield(i)
      dec(i)

# Note the direct call:
for j in makeCDFrom(6)():
  echo "j:", j

当我尝试在 https://play.nim-lang.org/ 上运行上述程序时，它似乎被卡住了。什么都没有显示。

为什么会有这种差异？

Answer 1

为什么？

因为有一个错误。

你能做些什么呢？

向 github.com/nim-lang/Nim 报告错误

同时使用任一

let myClosureIter = makeCDFrom(6)

或者在没有工厂的情况下定义你的迭代器：

iterator makeCDFrom(start: int): int =
    var
      i: int = start
    while i >= 0:
      echo "i:", i
      yield(i)
      dec(i)

# Note the direct call:
for j in makeCDFrom(6):
  echo "j:", j

Answer 2

稍作改动：

proc makeCDFrom(start: int): iterator(): int =
  echo "called again"
  result = iterator(): int =
    var
      i: int = start
    while i >= 0:
      echo "i:", i
      yield(i)
      dec(i)

并且在本地运行，它处于无限循环中：

called again
i:6
called again
j:6
called again
i:6
called again
j:6
called again
i:6
...