输出变量上的 CMD 子字符串提取

Question

寻找有关在批处理脚本中对命令输出的变量执行子字符串提取的指导。具体来说，我使用的命令是powershell (Get-CimInstance Win32_OperatingSystem).version

我已经使用for /f "tokens=*" %%i in ('"powershell (Get-CimInstance Win32_OperatingSystem).version"') do set OSvar=%%i成功设置了这个变量

如您所见，我正在查询操作系统版本，并且我有一个未公开的、半有效的用例用于使用此特定方法来查找它。即使我使用上述方法查询的推理可能会被误导，但我仍然想学习如何对这个输出执行子字符串提取，以供我自己启迪。找到解决方案不如在给定上下文中找到解决方案重要。

显然，这将输出“6.2.9200”、“6.3.9600”或“10.0.XXXXXXX”的效果。我想知道如何在小数点后第二位之前提取输出，但是我在研究后尝试的所有尝试都失败了，包括设置分隔符和使用第二个变量集等于第一个变量集 :~0,3%。这里的大师可以帮助一个人吗？

Answer 1

如果您只需要主要和次要数字，通过powershell，那么只返回那些似乎更明智，而不是事后解析结果：

For /F %%G In ('^""%__AppDir__%WindowsPowerShell\v1.0\powershell.exe" ^
 -NoProfile -NoLogo -Command "[System.Environment]::OSVersion.Version | " ^
 "ForEach-Object { '{0}.{1}' -F $_.Major,$_.Minor }"^"') Do Set "OSVar=%%G"

作为单行者：

For /F %%G In ('%__AppDir__%WindowsPowerShell\v1.0\powershell.exe -NoP "[System.Environment]::OSVersion.Version|%%{'{0}.{1}' -F $_.Major,$_.Minor}"')Do Set "OSVar=%%G"

如果你真的想坚持使用powershell 和Get-CimInstance：

For /F %%G In ('^""%__AppDir__%WindowsPowerShell\v1.0\powershell.exe" -NoP ^
 "(Get-CimInstance Win32_OperatingSystem).Version.Split('.')[0,1] -Join '.'"^"'
) Do Set "OSVar=%%G"

作为单行者：

For /F %%G In ('%__AppDir__%WindowsPowerShell\v1.0\powershell.exe -NoP "(GCim Win32_OperatingSystem).Version.Split('.')[0,1] -Join '.'"')Do Set "OSVar=%%G"

但是，如果您希望在检索到 do 部分后对其进行解析，那么我建议使用比使用标记和分隔符更简单的方法：

For /F %%G In ('^""%__AppDir__%WindowsPowerShell\v1.0\powershell.exe" ^
 -NoProfile -NoLogo "(Get-CimInstance Win32_OperatingSystem).Version"^"'
) Do Set "OSVar=%%~nG"

作为单行者：

For /F %%G In ('%__AppDir__%WindowsPowerShell\v1.0\powershell.exe -NoP "(GCim Win32_OperatingSystem).Version"')Do Set "OSVar=%%~nG"

在前面的两个示例中，.BuildNumber 被视为扩展名，因此使用元变量扩展我们可以返回不带扩展名的名称。

---

但是，您不需要powershell 来获取 WMI 信息，您可以改用wmic：

For /F %%G In ('"%__AppDir__%wbem\WMIC.exe" OS Get Version'
) Do If "%%~xG" NEq "" Set "OSVar=%%~nG"

再次作为单行者：

For /F %%G In ('%__AppDir__%wbem\WMIC.exe OS Get Version')Do If "%%~xG" NEq "" Set "OSVar=%%~nG"

Answer 2

好吧，将结果除以.

@echo off
for /f "tokens=1,2delims=." %%i in ('powershell (Get-CimInstance Win32_OperatingSystem^).version') do (
    set "OSvar=%%i.%%j"
)
echo %OSvar%

或来自同一代码的单行：

@echo off
for /f "tokens=1,2delims=." %%i in ('powershell (Get-CimInstance Win32_OperatingSystem^).version') do echo %%i.%%j

您也可以使用标准的ver 命令；

@for /f "tokens=1-5,*delims=. " %%i in ('ver') do @set OSvar=%%l.%%m

按要求解释。 看到我们用. 分割字符串，每个标记都被分配给一个元变量。换一种说法。假设它是windows 10.0.18362.959，那么tokens=1,2 会将10 分配给%%i，将0 分配给%%j

Answer 3

希望这是您要提取的内容：

@echo off
@For /f "tokens=1,2,3 delims=." %%a in (
    '"powershell (Get-CimInstance Win32_OperatingSystem).version"'
) Do ( 
    Set "FirstVar=%%a"
    Set "SecondVar=%%b"
    Set "ThirdVar=%%c"
    Set "AllVar=%%a.%%b.%%c
)

echo FirstVar  = %FirstVar%
echo SecondVar = %SecondVar%
echo ThirdVar  = %ThirdVar%
echo AllVar    = %AllVar%
pause