【问题标题】:In batch script, split only last string match in a variable在批处理脚本中,仅拆分变量中的最后一个字符串匹配项
【发布时间】:2019-07-08 19:23:54
【问题描述】:

在批处理脚本中,我只需要在循环中拆分变量中的最后一个字符串匹配项,直到我不再有字符串匹配项。

Input=Level1/Level2/Level3/Level4/LevelN

(其中 N 可以是任意数字)
输出:

Level1/LeveL2/Level3/Level4
Level1/LeveL2/Level3
Level1/Level2
Level1

我尝试了通常的"for /f "delims=/"" 循环,但它们只在单独的行上输出输入变量的每个拆分。此外,“N”的值可以变化。所以我不能将令牌的数量设置为某个值。

请帮忙。

【问题讨论】:

  • 您没有解释您的任务,没有发布有问题的代码,也没有显示任何字符串匹配。请edit your question 以使其达到足够的标准以保持开放并吸引您需要的回复。另请注意,Windows 使用反斜杠作为路径分隔符,请确保确定您使用的是正斜杠还是反斜杠作为分隔符。
  • 需要做的“匹配”是什么?问题中显示的“输出:”是所需的结果吗?
  • 是的,正斜杠“/”就是要匹配的字符串。输入是对另一个工具中的文件夹结构的引用(不是 Windows 路径)。任务是编写脚本删除字符串匹配(“/”)之后的最后一个子字符串并对其执行命令。

标签: string batch-file for-loop cmd split


【解决方案1】:

这个网站不是这样工作的。您必须发布一些代码并解释您遇到的问题。通过这种方式,您可以了解对您自己的代码所做的更改。如果您要求我们提供代码,任何代码,那么您可能会收到一个(“任何代码”),如下所示:

@echo off
setlocal EnableDelayedExpansion

set "Input=Level1/Level2/Level3/Level4/LevelN"

:loop
   set "Output="
   set "part=%Input:/=" & set "Output=!Output!/!part!" & set "part=%"
   set "Input=%Output:~1%"
   if "%Input%" equ "~1" goto exitLoop
   echo "%Input%"
goto loop

:exitLoop

【讨论】:

  • 谢谢你,@Aacini!这对我有用。抱歉,没有发布我的代码,但如前所述,我只尝试了以“/”作为分隔符的基本 for 循环,硬编码令牌的实际数字,然后输出它。下次发帖会做得更好!谢谢大家!
【解决方案2】:

这是一个很好的递归方法,它利用了~ modifiers,假设输入字符串作为带引号的 ("") 命令行参数提供,它不以 / 开头,不包含两个连续的// 并且没有字符"、\、*、?、<、>:

@echo off
rem // Store argument in variable:
set "INPUT=%~1"
if not defined INPUT exit /B
rem /* Precede with `\` and replace each `/` by `\`, so the resulting string appears to
rem    be an absolute path, which can be split by `~` modifiers of `for` variables;
rem    the inner `for` loop resolves the split path and removes any `\.` suffix: */
for %%I in ("\%INPUT:/=\%") do for %%J in ("%%~pI.") do set "REST=%%~pnxJ"
rem // Revert replacement of every `/` by `\` and remove the previously preceded `\`:
set "REST=%REST:\=/%"
set "REST=%REST:*/=%"
rem // If there is a string left, output it and call this script recursively:
if defined REST (
    setlocal EnableDelayedExpansion
    echo(!REST!
    endlocal
    call "%~f0" "%REST%"
)

【讨论】:

    【解决方案3】:

    更经典的方法,只是为了好玩......

    @echo off
    setlocal EnableDelayedExpansion
    
    set "Input=Level1/Level2/Level3/Level4/LevelN"
    
    rem Split the string, join it again and store partial results
    set "aux="
    set "n=0"
    for %%a in ("%Input:/=" "%") do (
       set "aux=!aux!/%%~a"
       set /A n+=1
       set "out[!n!]=!aux:~1!"
    )
    
    rem Show results in reverse order
    set /A n-=1
    for /L %%i in (%n%,-1,1) do echo !out[%%i]!
    

    【讨论】:

      【解决方案4】:

      这可以通过 PowerShell 中的正则表达式轻松完成。由于正则表达式默认是贪婪的,因此它将获取最后一个 SOLIDUS 的所有内容并将其存储在 $1 组中。

      SET "S=Level1/Level2/Level3/Level4/LevelN"
      
      FOR /F "delims=" %%a IN ('powershell -NoL -NoP "'%S%' -replace '(.*/).*', '$1'"') DO (
          SET "RESULT=%%a"
      )
      
      ECHO RESULT is set to %RESULT%
      

      修订:

      这会输出所有组,而不仅仅是最后一个。

      SET "S=Level1/Level2/Level3/Level4/LevelN"
      
      FOR /F "delims=" %%a IN ('powershell -NoL -NoP -Command ^
          "$a = '%S%'.Split('/'); " ^
          "for ($i = $a.Count - 2; $i -ge 0; $i--) { $a[0..$i] -join '/' }"') DO (
          ECHO %%a
      )
      

      【讨论】:

      • 嗨@lit,这仅适用于第一个子字符串(输出为 Level1/Level2/Level3/Level4)。我也在寻找通过循环运行它来获取其他子字符串。无论如何,Aacini 已经回答了上面的问题,我已经接受了这个答案。非常感谢!
      • @BS - 我已添加到输出所有组的答案代码中。
      猜你喜欢
      • 1970-01-01
      • 1970-01-01
      • 1970-01-01
      • 1970-01-01
      • 2012-11-24
      • 2021-03-17
      • 2014-08-15
      • 1970-01-01
      • 2021-03-02
      相关资源
      最近更新 更多