在批处理文件的 for 循环中设置随机变量值会产生错误

Question

这是我的代码：

for %%i in ("joined/*.mp4") do (
  set /a result=(%random%*2/32768)+1
  echo %result%
)

它给了我关于 +1 was unexpected at this time 的错误。

我尝试了另一种变体：

for %%i in ("joined/*.mp4") do (
  set /a result=(%random%*2/32768)
  echo %result%
)

它给了我一个关于不平衡括号的错误。

如何正确回显随机变量？

谢谢。 :)

尝试以下代码每次都会给我相同的随机值。如何在循环的每次迭代中更改它？

setlocal EnableDelayedExpansion
for %%i in ("joined/*.mp4") do (
  set /a result= %random%*20/32768 + 1
  echo !result!
)

是否有我可以阅读的资源来详细了解批处理文件的工作原理以及它们的语言（如循环、数组等）？我尝试在 Google 上搜索，但没有找到任何有用的信息。

Answer 1

正如@Stephan 提供的链接中所述，您需要 !也是随机的。

你可以这样做（由于某种原因，(!random!*20)/32768 触发 "/32768" was unexepected，所以你必须将它分成两行：

setlocal EnableDelayedExpansion
    for %%i in ("joined/*.mp4") do (
        set /a result = !random!*20
        set /a result= !result!/32768 +1
        echo !result!
    )

Answer 2

使用方括号（括号） 完全没问题，而且我会说更正确，所以你没有理由不能继续这样做。

为您提供一些选择，它们可以继续使用：

@Echo Off
SetLocal EnableExtensions EnableDelayedExpansion
For %%G In ("joined\*.mp4") Do (
    Set /A result = (!random! * 20 / 32768^) + 1
    Echo !result!
)
Pause

@Echo Off
SetLocal EnableExtensions EnableDelayedExpansion
For %%G In ("joined\*.mp4") Do (
    Set /A "result = (!random! * 20 / 32768) + 1"
    Echo !result!
)
Pause

@Echo Off
SetLocal EnableExtensions EnableDelayedExpansion
For %%G In ("joined\*.mp4") Do (
    Set /A result = (!random! %% 20^) + 1
    Echo !result!
)
Pause

@Echo Off
SetLocal EnableExtensions EnableDelayedExpansion
For %%G In ("joined\*.mp4") Do (
    Set /A "result = (!random! %% 20) + 1"
    Echo !result!
)
Pause