从调用的批处理文件中接收变量

Question

我这里有两个批处理文件，test.bat 和 len.bat。

len.bat 是一个函数，它接收来自test.bat 的输入，对其进行处理，然后将结果值返回给test.bat。

test.bat

@echo off
setlocal EnableDelayedExpansion
call len tesla
echo !result!
pause

len.bat

@echo off
setlocal EnableDelayedExpansion
set "string=%~1"
for /l %%a in (0,1,10000) do if "!string:~%%a,1!" == "" (
    set result=%%a
    exit /b
)

当我打开test.bat 时，我希望它会打印一个值。相反，它说 Echo 已关闭。 将变量从len.bat 传递到test.bat 似乎存在问题。

Answer 1

setlocal 可以被认为是一个沙箱，只要沙箱存在，在该沙箱内创建的任何东西都会存在。当调用 endlocal 时，沙箱停止存在 - 无论是显式调用，还是在脚本结束时隐式调用。

在len.bat 中，您使用第二个setlocal enabledelayedexpansion 命令在沙箱内添加一个沙箱，然后在该内部沙箱内创建!result!。当len.bat 结束时，!result! 被销毁，因为在调用len.bat 之前它并不存在。

我怀疑您添加了第二个setlocal enabledelayedexpansion，因为您认为需要在len.bat 内部使用延迟扩展，但实际上延迟扩展仍然启用，因为它在test.bat 中已打开。

从len.bat 和test.bat 中删除setlocal enabledelayedexpansion 将正确返回“5”。

如果您觉得需要将setlocal enabledelayedexpansion 保留在len.bat 中以将其与test.bat 分开使用，您可以显式调用endlocal 并将set 命令链接到它以欺骗解释器让变量逃离沙箱。

@echo off
setlocal EnableDelayedExpansion
set "string=%~1"
for /l %%a in (0,1,10000) do if "!string:~%%a,1!" == "" (
    endlocal & set result=%%a
    exit /b
)

Answer 2

这对您有帮助吗？字符串长度返回为%ErrorLevel%:

新的len.bat

@Set "str=#%~1" & SetLocal EnableDelayedExpansion
@Set "len=0" & For /L %%G In (12,-1,0) Do @(Set /A "len |= 1 << %%G"
    For %%H In (!len!) Do @If "!str:~%%H,1!" == "" Set /A "len &= ~ 1 << %%G")
@EndLocal & Exit /B %len%

示例 test.bat

@Call "len.bat" four
@Echo %ErrorLevel% & Pause
@Call "len.bat" "nineteen inc spaces"
@Echo %ErrorLevel% & Pause