如何从 worksheet_change 事件执行模块内的宏代码

Question

我的工作簿第 1 页上有一组原始数据。在表 2 上，我使用公式从表 1 中提取一些数据。

使用我在模块 1 中创建和发布的宏，我想隐藏任何不包含特定数据的行。当我需要通过 Run>Run Sub/Userform 时，我可以直接执行宏。效果很好。

但是，每当对工作表 1 进行编辑时，我希望它在需要通过后台的 worksheet_change 事件进行更新时运行。因为我在工作表 1 上进行编辑，但希望更改在工作表上执行宏2 我了解必须将 worksheet_change 事件放置在“此工作表”中，而不是放在特定工作表中。

这是宏代码

Sub HideRows()
Dim i As Integer
i = 1
Do While Not Cells(i, 5) = ""
    If Cells(i, 5).Value = 0 Then
        Rows(CStr(i) + ":" + CStr(i)).EntireRow.Hidden = True
    ElseIf Cells(i, 5).Value <> 0 And Rows(CStr(i) + ":" + CStr(i)).EntireRow.Hidden = True Then
        Rows(CStr(i) + ":" + CStr(i)).EntireRow.Hidden = False
    End If
i = i + 1
Loop
End Sub

直接运行上面的代码可以满足我的需要。我在下面通过 worksheet_change 事件执行此操作的代码不起作用。

Private Sub Worksheet_Change(ByVal Target As Range)
    With Me.Worksheets("Sheet2")
        Call HideRows
    End With
End Sub

任何有关如何使用 worksheet_change 执行宏的帮助将不胜感激。

Answer 1

值得注意的几点

1. 问题是您没有完全限定单元格，因此当调用HideRows 宏时，即使您使用了With Me.Worksheets("Sheet2")，它仍然指的是当前工作表Sheet1。完全限定您的范围对象，如下所示。注意到他们前面的Dots了吗？

2. 如果更改发生在 Col A 或 Sheet1 中，则捕获，否则您的宏将针对 Sheet1 中的任何更改运行，从而使您的工作簿变慢。

3. 您不需要将宏保存在模块中。你可以把整个代码放在Sheet1中，如下图

4. Rows(CStr(i) + ":" + CStr(i))也可以写成Rows(i)

5. 在 Excel 中处理行时，始终建议将它们声明为 Long 而不是 Integer。发布 Excel2007 行数增加了，Integer 变量可能无法容纳。

这是你正在尝试的吗？将此代码放在Sheet1的Sheet代码区

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim i As Long, lRow As Long

    '~~> Check of the change is happening in Col 1
    If Not Intersect(Target, Columns(1)) Is Nothing Then
        With Worksheets("Sheet2")
            lRow = .Range("E" & .Rows.Count).End(xlUp).Row

            For i = 1 To lRow
                If .Cells(i, 5).Value = 0 Then
                    .Rows(i).EntireRow.Hidden = True
                ElseIf .Cells(i, 5).Value <> 0 And .Rows(i).EntireRow.Hidden = True Then
                    .Rows(i).EntireRow.Hidden = False
                End If
            Next i
        End With
    End If
End Sub