在 clojure 中实现撤消/重做的模式

Question

一般来说，在 clojure 或 fp 中实现撤消/重做功能是否有既定模式？

在 OO 语言中，我会使用命令模式，但由于它是关于状态的，我想知道在 clojure 中这样做是否是惯用的。

有没有可以提供帮助的库？

Answer 1

与许多设计模式一样，您可以将其实现为 clojure 中的函数。这在一定程度上取决于您在程序中如何表示状态（refs、atoms、agents），过程非常相似。

您只需向您的状态添加一个观察器函数代理/引用/原子，每次有更新时将状态添加到撤消列表。那么您的撤消功能只是在撤消列表中查找它。这具有将您添加到撤消列表的良好效果，也允许重做

我的第一印象是refs 可能是解决此问题的正确工具，因为您将能够以协调的方式恢复它们，当然，除非您可以将程序状态减少到一个单一的身份（在Clojure 这个词的含义）那么您将不需要协调更新，并且代理可以工作。

Answer 2

好的，我让它像 Arthur Ulfeldt 建议的那样工作：

(defn cmd-stack [state-ref]
  (let [stack (atom ['() '()])]
    (add-watch state-ref :cmdhistory
           (fn [key ref old new]
             (let [redo-stack '()
                   undo-stack (conj (second @stack) old)]
             (reset! stack [redo-stack undo-stack]))))
    stack))

(defn can-redo? [stack]
  (not (empty? (first @stack))))

(defn can-undo? [stack]
  (not (empty? (second @stack))))

(defn undo! [stack state-ref]
  (let [redo-stack (first @stack)
        undo-stack (second @stack)
        current-state @state-ref
        last-state (first undo-stack)]
    (assert (can-undo? stack) "cannot undo")
    (reset! state-ref last-state)
    (reset! stack [(conj redo-stack current-state) (drop 1 undo-stack)])))

(defn redo! [stack state-ref]
  (let [redo-stack (first @stack)
        undo-stack (second @stack)
        current-state @state-ref
        last-state (first redo-stack)]
    (assert (can-redo? stack) "cannot redo")
    (reset! state-ref last-state)
    (reset! stack [(drop 1 redo-stack) (conj undo-stack current-state)])))

但我仍然不太明白为什么。由于撤消！并重做！函数更新正在被监视的原子，观察者不应该对此做出反应，从而通过将未完成的值放回命令堆栈来弄乱命令堆栈吗？