如何以原始大小保存图像？

Question

在我的 Flex 应用程序中，我将图像加载到 Image 控件中。加载图像后，我可以应用颜色变换或灰度等滤镜，然后我想保存应用了滤镜的图像。我无法保存应用了过滤器的图像。使用以下代码，图像在没有过滤器的情况下被保存。但是，如果我使用

最终图像数据 = ImageSnapshot.captureBitmapData(myImage);

然后，图像会在应用过滤器的情况下保存，但会使用图像控件的尺寸。我想用原始尺寸保存图像。需要明确的是，如果图像是 1000px X 1000px 并显示在 300px X 300px 图像控件中，在保存时我仍然想以 1000px X 1000px 尺寸保存图像。怎么做？我也尝试过直接从下面的图像控件内容中获取 BitmapData，但这似乎不起作用。有帮助吗？

最终图像数据 = 位图(myImage.content).bitmapData;

            var filtersArray:Array = new Array;
            private var finalImagedata:BitmapData;

            private function loadImage(url:String):void
            {
                var request:URLRequest = new URLRequest(url);

                var imageLoader:Loader = new Loader();
                imageLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, image_completeHanlder);
                imageLoader.load(request);
            }
            private function image_completeHanlder(event:Event):void
            {
                var bmd:BitmapData = Bitmap(event.currentTarget.content).bitmapData;
                var bmpMy:Bitmap = new Bitmap(bmd);
                myImage.data=bmpMy;

            }
            protected function button1_clickHandler(event:MouseEvent):void
            {
                loadImage("http://localhost/main/image.jpg"); 
            }

            protected function prepareFinalImage():void
            {
                finalImagedata = new BitmapData(myImage.content.width, myImage.content.height, true);
                finalImagedata.draw (myImage.content);
            }
            protected function btnSave_clickHandler(event:MouseEvent):void
            {
                prepareFinalImage();

                var encoder:Object = new Object();
                var defaultName:String;

                        var je:*;
                        je = new JPGEncoder(100);
                        encoder.encode = je.encode;
                        defaultName = "myImage.jpg";


                var imageBytes:ByteArray = encoder.encode(finalImagedata);
                var fr:FileReference = new FileReference();
                fr.save(imageBytes,defaultName);
            }


            protected function btnGrayScale_clickHandler(event:MouseEvent):void
            {
                var red:Number = 0.3086; // luminance contrast value for red
                var green:Number = 0.694; // luminance contrast value for green
                var blue:Number = 0.0820; // luminance contrast value for blue
                var cmf1:ColorMatrixFilter = new ColorMatrixFilter([red, green, blue, 0, 0, red, green, blue, 0, 0, red, green, blue, 0, 0, 0, 0, 0, 1, 0]);
                filtersArray.push(cmf1);
                myImage.filters = filtersArray;
            }

Answer 1

您应该将从Loader 检索到的位图数据存储为类成员：

private var bmd:BitmapData;
[...]
private function image_completeHanlder(event:Event):void
{
    bmd = Bitmap(event.currentTarget.content).bitmapData;
    var bmpMy:Bitmap = new Bitmap(bmd);
    myImage.data=bmpMy;
}

你的prepareFinalImage 方法应该依赖于加载的位图数据：

protected function prepareFinalImage():void
{
    finalImagedata = new BitmapData(bmd.width, bmd.height, true);
    if (myImage.filters.length > 0)
        finalImagedata.applyFilter(bmd, 
            new Rectangle(0, 0, bmd.width, bmd.height), 
            new Point(0,0), myImage.filters[0] as BitmapFilter);
    if (myImage.filters.length > 1)
        for (var i:int = 1; i < myImage.filters.length; i++)
        {
            finalImagedata.applyFilter(finalImagedata, 
                new Rectangle(0, 0, bmd.width, bmd.height), 
                new Point(0,0), myImage.filters[i] as BitmapFilter);
        }
}

这样您将在BitmapData 上应用过滤器，而不是在缩放后的DisplayObject 上。