批量查找给定字符串条件的文件

Question

我有一个包含一些单词的变量，例如KEYWORDS ="Blue Blond Brown White Black Eyes Hair Skin"，另一个只包含其中一些单词，例如 MYWORDS="BLUE BROWN EYES HAIR"

我的目录中有一些文件，例如

BlueEyesBlondHair.txt
BrownEyesBlondHair.txt
BlueEyesBrownHair.txt
BlueEyesBrownHairWhiteSkin.txt
BlueEyes.txt
BrownHair.txt
BrownEyes.txt
GreenEyesBlondHair.txt

如何检索名称包含变量MYWORDS中所有单词的文件，而不是其他？

注意：这是一个完全虚构的例子，但我认为它与我的现实非常吻合。请把所有内容都当作大写字母。

Answer 1

我找到了另一种不需要检查文件名长度的方法：findstr 有一个 /v 选项，允许它搜索与模式不匹配的内容。

由于我同时拥有KEYWORDS 和MYWORDS 变量，我可以轻松创建第三个名为BADWORDS 的变量，其中包含KEYWORDS 中但MYWORDS 中没有的所有单词。

按照示例，我们有BADWORD= BLOND WHITE BLACK SKIN

那么做一个简单的就足够了：

dir /b *.txt | findstr /i /C:"BLUE" /C:"BROWN" /C:"HAIR" /C:"EYES" | findstr /i /v "%BADWORDS%"

获取包含来自MYWORDS 的所有单词但不包含其他单词的文件名。

但是，这仍然需要拆分变量MYWORDS，就像在@Gerhard 回答中一样。

另一种方法是像这样修改MYWORDS：

set MYNEWWORDS=%MYWORDS: =.*%

然后做

dir /b *.txt | findstr /i /R /C:"%MYNEWWORDS%" | findstr /i /v "%BADWORDS%"

这将搜索包含来自MYWORDS 的所有单词的文件名，但顺序相同。这意味着这还不足以解决我的案子。

Answer 2

有趣的谜题。

你的白名单词显然可以以任何顺序出现，这使得它有点困难，但并非无法解决：

@echo off
setlocal enabledelayedexpansion

REM ---- only to generate testfiles: ---
for %%a in (
BlueEyesBlondHair.txt
BrownEyesBlondHair.txt
BlueEyesBrownHair.txt
BlueEyesBrownHairWhiteSkin.txt
BlueEyes.txt
BrownHair.txt
BrownEyes.txt
GreenEyesBlondHair.txt
LongHairBlueShirtBrownEyes.txt
CompletelyUnrelatedFile.txt
) do break>"%%a"
REM ---- end generate testfiles ----

set "KEYWORDS=Blue Blond Brown White Black Eyes Hair Skin"
set "MYWORDS=BLUE BROWN EYES HAIR"
REM generate exclude-list:
set "NONWORDS=%KEYWORDS%"
for %%a in (%MYWORDS%) do set "NONWORDS=!NONWORDS:%%a=!"
rem echo %NONWORDS%

for %%a in (*.txt) do (
  set /a c1=c2=0
  set "name=%%~na"
  for %%b in (%MYWORDS%) do (
    REM increment counter1 [number of words in MYWORDS]:
    set /a c1+=1
    REM increment counter2 [number of those words in the filename]
    if not "!name:%%b=!" == "!name!" set /a c2+=1
  )
  if !c1! == !c2! (
    echo %%a has all of MYWORDS
    echo %%a|findstr "%NONWORDS%" >nul|| (
      echo %%a has none of NONWORDS
    ) && (
      echo +++ %%a has all of MYWORDS and none of NONWORDS
    ) 
  ) else (
    echo %%a has not all of MYWORDS
  )
)

这段代码的输出：

BlueEyes.txt has not all of MYWORDS
BlueEyesBlondHair.txt has not all of MYWORDS
BlueEyesBrownHair.txt has all of MYWORDS
BlueEyesBrownHair.txt has none of NONWORDS
+++ BlueEyesBrownHair.txt has all of MYWORDS and none of NONWORDS
BlueEyesBrownHairWhiteSkin.txt has all of MYWORDS
BrownEyes.txt has not all of MYWORDS
BrownEyesBlondHair.txt has not all of MYWORDS
BrownHair.txt has not all of MYWORDS
CompletelyUnrelatedFile.txt has not all of MYWORDS
GreenEyesBlondHair.txt has not all of MYWORDS
LongHairBlueShirtBrownEyes.txt has all of MYWORDS
LongHairBlueShirtBrownEyes.txt has none of NONWORDS
+++ LongHairBlueShirtBrownEyes.txt has all of MYWORDS and none of NONWORDS

显然，根据您的需要调整 echos 或跳过您根本不需要的那些（为了更好地进行故障排除，我把它写得有点冗长）。

Answer 3

不过，只要把一个方法放在那里，你就可以使用findstrs 正则表达式来代替所有的`find 命令。这实际上只是一个演示：

@echo off & set prev=100
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b *.txt ^|find /i "blue" ^|find /i "brown"^|find /i "eyes"^|find /i "hair"') do echo %%i>_&for %%a IN (_) do (
   set /a len=%%~za-2
   if !len! lss !prev! (
     set prev=!len!
     set "file=%%i"
  )
)
echo !file! & (del _ /Q)>nul 2>&1