如何将文件夹选择对话框添加到 bat 文件？

Question

我有这个 bat 文件，它在给定的目录路径中创建文件夹结构。我只是想以某种方式将路径代码（set /p fd= "Enter Path: "）替换为打开一个对话框的代码，我可以在其中选择文件夹。 谢谢。

@echo off

set /p pr="Enter Project Name: "
set /p fd= "Enter Path: " 
MkDir "%fd%\%pr%\"
MkDir "%fd%\%pr%\%pr%_HD\"
MkDir "%fd%\%pr%\%pr%_HD\01_FILE\"
MkDir "%fd%\%pr%\%pr%_HD\02_ASSETS\"
MkDir "%fd%\%pr%\%pr%_HD\03_LOGS\"
MkDir "%fd%\%pr%\%pr%_UHD\"
MkDir "%fd%\%pr%\%pr%_UHD\01_FILE\"
MkDir "%fd%\%pr%\%pr%_UHD\02_ASSETS\"
MkDir "%fd%\%pr%\%pr%_UHD\03_LOGS\"

Answer 1

这是一个快速的 batch-file 示例，无需解释，因为您在技术上只是请求代码：

0</* :
@Set "pr=test"
@Set /P "pr=Enter Project Name: "
@For /F "Delims=" %%G In ('%SystemRoot%\System32\cscript.exe //E:JScript //NoLogo "%~f0" 2^>NUL ^| %SystemRoot%\System32\find /V ""')Do @For %%H In ("HD" "UHD") Do @For %%I In ("01_FILE" "02_ASSETS" "03_LOGS") Do @MD "%%G\%pr%\%pr%_%%~H\%%~I"
@Exit /B */0;
var Folder=new ActiveXObject('Shell.Application').BrowseForFolder(0,'Select your directory.',1,'0');
try{new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1).Write(Folder.Self.Path)};catch(e){};close();

您应该知道，您的代码并因此无法确定最终用户是否输入了在 Windows 中允许作为目录名称的字符串。 我也预先设置了一个字符串值test，所以如果你的最终用户没有在Enter Project Name提示符下提供输入，它至少会为你创建一些目录。

Answer 2

如果您希望 GUI 选择文件夹，您可以调用 Powershell。这两个中的任何一个都应该适合你。

set "psCommand="(new-object -COM 'Shell.Application').BrowseForFolder(0,'Please choose your SOURCE folder.',0x010,17).self.path""
for /f "usebackq delims=" %%I in (`powershell %psCommand%`) do set "location=%%I
echo %location%
pause

--

set "psCommand="(new-object -COM 'Shell.Application').BrowseForFolder(0,'Please choose the folder.',0,0).self.path"" 
for /f "usebackq delims=" %%I in (`powershell %psCommand%`) do set "folder=%%I"
echo %folder%
pause

这是您的代码与我的代码合并。我假设您不会这样做，因为这是经过测试和验证的。

@echo off
set /p pr="Enter Project Name: "
set "psCommand="(new-object -COM 'Shell.Application').BrowseForFolder(0,'Please choose your SOURCE folder.',0x010,17).self.path""
for /f "usebackq delims=" %%I in (`powershell %psCommand%`) do set "fd=%%I

MkDir "%fd%\%pr%\%pr%_HD\01_FILE\"
MkDir "%fd%\%pr%\%pr%_HD\02_ASSETS\"
MkDir "%fd%\%pr%\%pr%_HD\03_LOGS\"
MkDir "%fd%\%pr%\%pr%_UHD\01_FILE\"
MkDir "%fd%\%pr%\%pr%_UHD\02_ASSETS\"
MkDir "%fd%\%pr%\%pr%_UHD\03_LOGS\"